Copy Paste Running Data Macro

[scummins22]

Hello,

I am building a customer login sheet/tracker. I have a tablet that I will be running the login sheet off of for the customer's to fill in their information and I have put a shape at the bottom that looks like a button. I want to add a macro to where when they click the button, it copies their information, pastes it to another sheet that will be driven on a share drive, but I don't want it to paste over existing information but fill in the next available space. I am somewhat good at writing macros but I don't know where to start on this one. Can someone help me build the macro to do what I am needing?

The cells in the login screen that I want to copy and paste:
B5:G17

 

[Michael M]

Please provide login sheet name, destination sheet name and column of destination sheet to be pasted to.

 

[scummins22]

Please provide login sheet name, destination sheet name and column of destination sheet to be pasted to.

Login Sheet Name : Customer Login
Destination Sheet Name: Data Sheet
Column Destinatin: A

Thank you for your help!!

 

[Michael M]

Try, untested

Sub MM1()
Dim lr As Long
lr = Sheets("Data Sheet").Cells(Rows.Count, "A").End(xlUp).Row + 1
Sheets("Customer Login").Range("B5:G17").Copy Sheets("Data Sheet").Range("A" & lr)
End Sub

 

[scummins22]

How do I get it to just paste values in that macro? I don't need the formatting, just the values.

 

[JackDanIce]

Try:

Sub M2()
    
    Dim x   As Long

    With Sheets("Data Sheet")
        x = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Cells(1, x).Resize(13, 6).Value = Sheets("Customer Login").Cells(5, 2).Resize(13, 6).Value
    End With
    
End Sub

 

[scummins22]

Ok, so that pasted it perfectly. The issue now is that it is pasting over existing data. So how can we make it to where it will just go to the next available line without covering existing data?

 

[JackDanIce]

My error, try:

Sub M3()
    
    Dim x   As Long

    With Sheets("Data Sheet")
        x = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
        .Cells(x, 1).Resize(13, 6).Value = Sheets("Customer Login").Cells(5, 2).Resize(13, 6).Value
    End With
    
End Sub