Copy open workbook to same folder dir with date amended to name

[IIII]

Hi All - as it states in the heading, I'm looking to either amend the code below or obtain a new on where I can copy the workbook I have open to the same folder but with the Week ending date (Sunday) added to the end of the file name.

I found this code (Credit: @swapnilk) that gets me going into the right direction but I just need it to save and do the above without prompting. Hope this makes sense, otherwise please let me know if more info is required. Thanks all.

Sub SaveCopy()
    'Declare a variable to hold the current workbook
    Dim wb As Workbook
    'Set the variable equal to the current open workbook
    Set wb = ActiveWorkbook
    
    'Prompt the user for the location to save the copy of the workbook
    Dim savePath As String
    savePath = Application.GetSaveAsFilename( _
        InitialFileName:=wb.Name, _
        FileFilter:="Excel Files (*.xlsx), *.xlsx")
    
    'Save a copy of the workbook to the specified location
    wb.SaveCopyAs savePath
End Sub

 

[John_w]

Try this macro:

Public Sub Save_As_New_Workbook_With_Date()

    Dim nextSunday As Date
    Dim p As Long
    Dim newFullName As String
        
    nextSunday = Date + 8 - Weekday(Date)
    
    With ActiveWorkbook
        p = InStrRev(.FullName, ".")
        newFullName = Left(.FullName, p - 1) & Format(nextSunday, " YYYY-MM-DD") & Mid(.FullName, p)
        .SaveCopyAs newFullName
    End With

End Sub

 

[IIII]

Try this macro:

Public Sub Save_As_New_Workbook_With_Date()

    Dim nextSunday As Date
    Dim p As Long
    Dim newFullName As String
       
    nextSunday = Date + 8 - Weekday(Date)
   
    With ActiveWorkbook
        p = InStrRev(.FullName, ".")
        newFullName = Left(.FullName, p - 1) & Format(nextSunday, " YYYY-MM-DD") & Mid(.FullName, p)
        .SaveCopyAs newFullName
    End With

End Sub

Thank you @John_w - this works perfectly. Appreciate it! Cheers.