Copy only the data shown with adding a blank row between all copied rows

[sofas]

Hello. I have this code to copy only the data shown in the same format to Sheet 2 I want to modify the code so that I can copy the data with an empty row between all the copied rows

Sub COPY()

Dim SH1 As Worksheet, SH2 As Worksheet
Dim lr As String
Set SH1 = Sheet1
Set SH2 = sheet2
lr = SH1.Range("A5").SpecialCells(xlCellTypeLastCell).Address

SH2.Cells.Clear

SH1.Range("A5:" & lr).SpecialCells(xlCellTypeVisible).COPY _
Destination:=SH2.Range("A5")
SH1.Range("A5:G5").COPY Destination:=SH2.Range("A5")
Application.CutCopyMode = Fals
SH2.Columns("A:G").EntireColumn.AutoFit
End Sub

As for adding empty rows, I used this code, but it is slow due to the number of rows copied

Dim r As Long, y As Long
    y = SH2.Range("A" & SH2.Rows.Count).End(xlUp).Row
    For r = y To 7 Step -1
        SH2.Cells(r, 1).EntireRow.Insert Shift:=xlDown

    Next r

 

[footoo]

Here's one way. Write code to:
Use a helper column to put sequential numbers for the data rows
Copy the numbers and paste below
Sort based on the helper column
Delete helper column

 

[sofas]

Here's one way. Write code to:
Use a helper column to put sequential numbers for the data rows
Copy the numbers and paste below
Sort based on the helper column
Delete helper column

Hello, thank you for your interest, but frankly I do not have enough experience to do such a thing. I hope to find someone to help me with that.

This is the code that is currently used

Sub Copy()
Dim wsData As Worksheet
Dim wsDest As Worksheet
Dim lr As Long

Application.ScreenUpdating = False
Set wsData = Sheet1
Set wsDest = sheet2

lr = wsData.Cells(Rows.Count, "A").End(xlUp).Row

wsDest.Cells.Clear

   wsData.Range("A5:G" & lr).SpecialCells(xlCellTypeVisible).Copy wsDest.Range("A5")

 wsDest.Columns("A:G").EntireColumn.AutoFit
 wsDest.Activate

Application.ScreenUpdating = True
End Sub

 

[footoo]

Try this:

Sub Copy()
Dim wsData As Worksheet
Dim wsDest As Worksheet
Dim lr As Long
Application.ScreenUpdating = False
Set wsData = Sheet1
Set wsDest = Sheet2
lr = wsData.Cells(Rows.Count, "A").End(xlUp).Row
wsDest.Cells.Clear
wsData.Range("A5:G" & lr).SpecialCells(xlCellTypeVisible).Copy wsDest.Range("A5")
wsDest.Columns("A:G").EntireColumn.AutoFit
wsDest.Activate

Dim rng As Range
lr = Cells(Rows.Count, "A").End(3).Row
Set rng = Range("H5:H" & lr)
rng = Evaluate("ROW(" & rng.Address & ")")
rng.Copy Cells(lr + 1, "H")
ActiveSheet.Sort.SortFields.Clear
rng.Resize(rng.Count * 2).EntireRow.Sort Key1:=[H5]
[H:H].Delete

Application.ScreenUpdating = True
End Sub

 

[sofas]

Try this:

Sub Copy()
Dim wsData As Worksheet
Dim wsDest As Worksheet
Dim lr As Long
Application.ScreenUpdating = False
Set wsData = Sheet1
Set wsDest = Sheet2
lr = wsData.Cells(Rows.Count, "A").End(xlUp).Row
wsDest.Cells.Clear
wsData.Range("A5:G" & lr).SpecialCells(xlCellTypeVisible).Copy wsDest.Range("A5")
wsDest.Columns("A:G").EntireColumn.AutoFit
wsDest.Activate

Dim rng As Range
lr = Cells(Rows.Count, "A").End(3).Row
Set rng = Range("H5:H" & lr)
rng = Evaluate("ROW(" & rng.Address & ")")
rng.Copy Cells(lr + 1, "H")
ActiveSheet.Sort.SortFields.Clear
rng.Resize(rng.Count * 2).EntireRow.Sort Key1:=[H5]
[H:H].Delete

Application.ScreenUpdating = True
End Sub

Thank you very much, it was successful.