Copy Last 10 Cells from A Table and Paste into Another Table.

[itsgrady]

Table 1 - PortsPounds
Table 2 - 10DaysPounds

I need to copy the last 10 rows of table 1, column a to the table 2 Column

Table holds all of the date on a large table. I add data to this table about 3 times a week.

Table two 2 should hold the last 10 days (not consecutive days) of information people would like to see and use. If I can get the 10 days in the Table in column A I will use Xlookup up to get the remaining data.

I tried this but I could not get it to work:
=INDEX(PortsPound!A:A,COUNTA(PortsPound!A:A)-9):INDEX(PortsPound!A:A,COUNTA(PortsPound!A:A))

 

[Glenn Kennedy]

One way (of many):

=INDEX(PortsPound!A:A,AGGREGATE(14,6,ROW(PortsPound!A1:A100)/(PortsPound!A1:A100<>""),11-SEQUENCE(10)))

 

[hagia_sofia]

How about:

=INDEX(A1:A100,SEQUENCE(10,,INDEX(A1:A100,ROWS(A1:A100),0)-9,1),0)

 

[Eric W]

Another one, this returns all the columns:

Book1
	A	B	C	D	E	F	G	H
1	Date	Code	Number			Date	Code	Number
2	1/1/2024	A	2			1/12/2024	B	37
3	1/2/2024	B	3			1/13/2024	A	41
4	1/3/2024	A	5			1/14/2024	B	43
5	1/4/2024	B	7			1/15/2024	A	47
6	1/5/2024	A	11			1/16/2024	B	53
7	1/6/2024	B	13			1/17/2024	A	59
8	1/7/2024	A	17			1/18/2024	B	61
9	1/8/2024	B	19			1/19/2024	A	67
10	1/9/2024	A	23			1/20/2024	B	71
11	1/10/2024	B	29			1/21/2024	A	73
12	1/11/2024	A	31
13	1/12/2024	B	37
14	1/13/2024	A	41
15	1/14/2024	B	43
16	1/15/2024	A	47
17	1/16/2024	B	53
18	1/17/2024	A	59
19	1/18/2024	B	61
20	1/19/2024	A	67
21	1/20/2024	B	71
22	1/21/2024	A	73
23
PortsPound

Cell Formulas
Range	Formula
F2:H11	F2	=INDEX(PortsPound!A2:C100,SEQUENCE(10,,COUNTA(PortsPound!A:A)-10),{1,2,3})
Dynamic array formulas.

 

[Alex Blakenburg]

This is a bit longer but works from the bottom up so it will still work if you move your table further down the sheet.

=LET(rngA,PortsPound!A:A,
     lastCell,XLOOKUP(TRUE,rngA<>"",rngA,,0,-1),
     lastRow,ROW(lastCell),
     INDEX(rngA,lastRow-9):lastCell)

 

[itsgrady]

Thanks for all the help on this matter. I tried each of them and they all worked. I do appreciate the time.