Copy Excel Range to Existing Powerpoint File and Specific Slide

[PDeee]

Hi All,

I don't have any knowledge in VBA so can someone help me to generate an Excel range to an existing Powerpoint file and I want to paste it on a specific slide?
I am using 2010 versions. I have checked some of the forums in here but it's not working for me.

I have to copy an excel ranges and paste it in the PPT as a table with colored shape. I have 3 excel ranges to be paste in existing 3 slides of the PPT.

Thanks for the help!

-PD

 

[Yongle]

A working starting point
The VBA below:
- creates a new presentation (yes - I know you do not want that )
- and inserts a range into a slide

Do the following
- create a new worksheet
- add a typical range of values in a contiguous range starting in cell A1
- quicky format that range with borders, bold , colours, to make it look the way you want it to look in powerpoint
- paste the code below into a module and run it

Sub ExcelRangeToPowerPoint()
'PURPOSE: Copy/Paste An Excel Range Into a New PowerPoint Presentation
'SOURCE: www.TheSpreadsheetGuru.com

Dim rng As Range
Dim PowerPointApp As Object
Dim myPresentation As Object
Dim mySlide As Object
Dim myShape As Object

'Set Range in excel
  Set rng = ThisWorkbook.ActiveSheet.Range("A1").CurrentRegion

'Create an Instance of PowerPoint
  On Error Resume Next
    
    'Is PowerPoint already opened?
    Set PowerPointApp = GetObject(class:="PowerPoint.Application")
    
    'Clear the error between errors
    Err.Clear

    'If PowerPoint is not already open then open PowerPoint
    If PowerPointApp Is Nothing Then Set PowerPointApp = CreateObject(class:="PowerPoint.Application")
    
    'Handle if the PowerPoint Application is not found
    If Err.Number = 429 Then
        MsgBox "PowerPoint could not be found, aborting."
        Exit Sub
    End If

  On Error GoTo 0

'Optimize Code
    Application.ScreenUpdating = False
  
'Create a New Presentation
    Set myPresentation = PowerPointApp.Presentations.Add

'Add a slide to the Presentation
    Set mySlide = myPresentation.Slides.Add(1, 11) '11 = ppLayoutTitleOnly
    
'Copy Excel Range
    rng.Copy

'Paste to PowerPoint and position
    Set mySlide = myPresentation.Slides(1)
    mySlide.Shapes.PasteSpecial DataType:=2  '2 = ppPasteEnhancedMetafile
    Set myShape = mySlide.Shapes(mySlide.Shapes.Count)
  
    'Set position:
    myShape.Left = 66
    myShape.Top = 152

'Make PowerPoint Visible and Active
    PowerPointApp.Visible = True
    PowerPointApp.Activate

'Clear The Clipboard
    Application.CutCopyMode = False
  
End Sub

If you prefer to modify the code yourself have a look at this link and this one too

Or if you want some further help.. what I need to know next
1. what needs modifying? (other than making the VBA update an existing file)
- is range formatted as you want ?
- is table size correct?
- any other issue with it?
2. how are your Excel ranges identified?
- are they a consistent size?
- are they named ranges? (what are the names?)
- are they Excel tables? (table names?)
- etc...