Copy and paste with input box

[Lacampeona]

Hello Excel experts
I am new here
I have one question if that is possible

I have a range of cells that i want to copy after some cells bellow
A2:D2

see the attachement

I would like to create some input box to the user

like bellow
but in my case it copies entire row i want the selection of cells

thank you in advance excel experts

Dim iRow As Long
Dim iCount As Long
Dim i As Long

iCount = InputBox(Prompt:="How many rows you want to add?")
iRow = InputBox _
(Prompt:="After which row you want to add new rows? (Enter the row number")

For i = 1 To iCount
Rows(iRow).EntireRow.Insert
Next i

 

[rlv01]

Perhaps something like this.

Sub Copy_and_paste_with_input_box()
    Dim iRow As Long, iCount As Long, iCopy As Long
    Dim Ans As String

    Ans = InputBox(Prompt:="Which row do you want to copy from?")
    If Ans <> "" And IsNumeric(Ans) Then
        iCopy = CLng(Ans)
    Else
        Exit Sub
    End If

    Ans = InputBox(Prompt:="How many copies do you want?")
        If Ans <> "" And IsNumeric(Ans) Then
        iCount = CLng(Ans)
    Else
        Exit Sub
    End If
    
    Ans = InputBox(Prompt:="After which row do you want to paste the data?")
    If Ans <> "" And IsNumeric(Ans) Then
        iRow = CLng(Ans)
    Else
        Exit Sub
    End If

    Cells(iRow, 1).Resize(iCount, 1).EntireRow.Insert
    Cells(iCopy, 1).Resize(1, 4).Copy Cells(iRow, 1).Resize(iCount, 1)
End Sub

Before

Book2
	A	B	C	D
1
2	Name	Surname	Year	Sport
3	Luka	doncic	2024	Basketball
4
5
6
7
8
9
10
11
Sheet1

After

Book2
	A	B	C	D
1
2	Name	Surname	Year	Sport
3	Luka	doncic	2024	Basketball
4
5
6
7	Luka	doncic	2024	Basketball
8	Luka	doncic	2024	Basketball
9	Luka	doncic	2024	Basketball
10
11
Sheet1

 

[Lacampeona]

Hello expert
yes that is exactly what I need.
Thank you very much