Copy and Paste a table within a Word from Excel

[sharky12345]

Guys,

I'm am playing with a routine that opens a Word document and then copies an existing Table within that document before pasting it underneath. The problem that I'm having is that the pasting is in effect attaching it to the previous Table with no break, whereas I need a new line started so the new Table is completely separate.

Here's what I have if someone can help me?

With WordDoc

.Tables(2).Range.Copy
.Tables(2).Range.Paste

End With

I was unsure if this should be posted in this forum, because it's playing with Word, or if it should go in another because it's being done from Excel - if it's in the wrong one then sorry!

 

[Macropod]

Try:

Sub Demo()
Dim Rng1 As Range, Rng2 As Range
With ActiveDocument
  Set Rng1 = .Tables(2).Range
  With Rng1
    .Start = .Start - 1
    Set Rng2 = .Duplicate
    With Rng2
      .Collapse wdCollapseStart
      .FormattedText = Rng1.FormattedText
    End With
  End With
End With
End Sub

 

[sharky12345]

Hi, thanks for the reply - I've tried it but I'm getting a run time error 13, Type Mismatch on the following line;

 Set Rng1 = .Tables(2).Range

Thanks!

 

[Macropod]

The code was written as a stand-alone Word macro. To use it in an automation context, try changing:
Dim Rng1 As Range, Rng2 As Range
to:
Dim Rng1 As Word.Range, Rng2 As Word.Range
or, if you're using late binding:
Dim Rng1 As Object, Rng2 As Object
and changing:
ActiveDocument
to:
WordDoc

 

[sharky12345]

Perfect - thanks Paul.

 

[sharky12345]

Paul - can I request a further tweak if at all possible?

I need to repeat this routine up to 20 times, depending on the value of a cell. So is there an efficient method I could use to repeat it?

 

[Macropod]

Perhaps you could explain your requirements in more detail. What do you want - up to 20 copies of the same table or copies of up to 20 tables?

 

[sharky12345]

Sorry, that would help - 20 copies of the same table please.

 

[Macropod]

Try something along the lines of:

Dim Rng1 As Word.Range, Rng2 As Word.Range, i As Long, j As Long
i = CLng(InputBox("How many copies?", "Table Replicator", 1))
With WordDoc
  For j = 1 To i
    Set Rng1 = .Tables(2).Range
    With Rng1
      .Start = .Start - 1
      Set Rng2 = .Duplicate
      With Rng2
        .Collapse wdCollapseStart
        .FormattedText = Rng1.FormattedText
      End With
    End With
  Next
End With

 

[sharky12345]

Thanks Paul - appreciated.