copy and past multiple sheets

[jtodd]

HI
I have a workbook with several sheets with same layout but different data,
How can I copy data from all sheets into 1, the amout of data varies so would need to past all data into next empty row.
I have this code

Sub SummurizeSheets()
Dim ws As Worksheet

Application.ScreenUpdating = False
Sheets("Summary1").Activate

For Each ws In Worksheets
If ws.Name <> "Summary1" Then
ws.Range("A:L").Copy
Worksheets("Summary1").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).PasteSpecial (xlPasteValues)
End If
Next ws
End Sub

I just get debug , !!!!

 

[My Aswer Is This]

Try this:

Sub SummurizeSheets()
'Modified  7/13/2018  5:48:54 AM  EDT
Application.ScreenUpdating = False
Dim ws As Worksheet
Dim Lastrow As Long
Dim i As Long
Sheets("Summary1").Activate
    For i = 1 To Sheets.Count
        If Sheets(i).Name <> "Summary1" Then
            Lastrow = Sheets(i).Cells(Rows.Count, "A").End(xlUp).Row
            Sheets(i).Cells(1, 1).Resize(Lastrow, 12).Copy
            Worksheets("Summary1").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).PasteSpecial (xlPasteValues)
        End If
    Next
Application.ScreenUpdating = True
End Sub

 

[jtodd]

Thanks that works ,
Next , there are two sheets that i do not want included , is there a simple way of excluding them ?

 

[My Aswer Is This]

Try this look at the code and change You and Me to the proper sheet names you want excluded.

Sub SummurizeSheets()
'Modified  7/13/2018  6:17:33 AM  EDT
Application.ScreenUpdating = False
Dim ws As Worksheet
Dim Lastrow As Long
Dim i As Long
Sheets("Summary1").Activate
    For i = 1 To Sheets.Count
        If Sheets(i).Name <> "Summary1" And Sheets(i).Name <> "Me" And Sheets(i).Name <> "You" Then
            Lastrow = Sheets(i).Cells(Rows.Count, "A").End(xlUp).Row
            Sheets(i).Cells(1, 1).Resize(Lastrow, 12).Copy
            Worksheets("Summary1").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0).PasteSpecial (xlPasteValues)
        End If
    Next
Application.ScreenUpdating = True
End Sub