CONVOLUTION

[lrobbo314]

CONVOLUTION returns the convolution of 2 sets of numbers. I was watching a 3Blue1Brown video where they explain the process and I thought it would be fun to come up with a lambda for it. The 2 sets of numbers should be vertical ranges with the same amount of cells in each range. In the example below, there is matrix multiplication being done to the 2 sets, and the result is the addition of the diagonals, which are color coded.

CONVOLUTION
	A	B	C	D	E	F	G	H	I	J	K	L
1		4	5	6		Element	Math	Result		Set1	Set2	Convolution
2	1	4	5	6		1	1*4	4		1	4	4
3	2	8	10	12		2	1*5+2*4	13		2	5	13
4	3	12	15	18		3	1*6+2*5+3*4	28		3	6	28
5						4	2*6+3*5	27				27
6						5	3*6	18				18
Sheet6

Cell Formulas
Range	Formula
L2:L6	L2	=CONVOLUTION(J2:J4,K2:K4)
Dynamic array formulas.

=LAMBDA(set_1,set_2,
    LET(
        a,set_1,
        b,set_2,
        c,COUNTA(a),
        MAP(
            SEQUENCE(c*2-1,,-c+1),
            LAMBDA(x,
                LET(
                    sx,DROP(SEQUENCE(,c),,x),
                    cx,COUNTA(sx),
                    rx,INDEX(sx,SEQUENCE(,cx,cx,-1)),
                        SUM(INDEX(a,sx)*INDEX(b,rx))
                )
            )
        )
    )
)

 

[lrobbo314]

Last one reads a bit easier, but it can be reduced to.

=LAMBDA(
    set_1,set_2,
    LET(
        c,COUNTA(set_1),
        MAP(
            SEQUENCE(c*2-1,,-c+1),
            LAMBDA(
                x,
                LET(
                    sx,DROP(SEQUENCE(,c),,x),
                    cx,COUNTA(sx),
                        SUM(INDEX(set_1,sx)*INDEX(set_2,INDEX(sx,SEQUENCE(,cx,cx,-1))))
                )
            )
        )
    )
)

 

[lrobbo314]

I noticed that the above formulas would fail if the 2 datasets weren't the same number of cells.

The below revision fixes this issue. And, is a complete departure from my original strategy.

CONVOLUTION
	J	K	L	M	N	O
19		1	2	3		Result
20	1	1	2	3		1
21	2	2	4	6		4
22	3	3	6	9		10
23	4	4	8	12		16
24						17
25						12
Sheet5

Cell Formulas
Range	Formula
K20:M23	K20	=MMULT(J20:J23,K19:M19)
O20:O25	O20	=CONVOLUTION(J20:J23,K19:M19)
Dynamic array formulas.

=LAMBDA(
    set_1,set_2,
    LET(
        a,set_1,
        b,set_2,
        ca,COUNTA(a),
        cb,COUNTA(b),
        m,MMULT(set_1,set_2),
        s,SEQUENCE(ca+cb-1),
        g,MAKEARRAY(
            ca,cb,
            LAMBDA(
                r,c,
                IF(OR(AND(r=1,c>1),AND(c=1,r>1)),
                    r*c,
                    r*c-((r-1)*(c-1))
                )
            )),
            MAP(
                s,
                LAMBDA(
                    x,
                        SUMPRODUCT((g=x)*m)
                )
            )
        )
)