Converting HTML Code to Table in MS Word

[khawarameer]

Dear All,

I have an html code available in an excel column (Please refer below table). My aim is to send that code to Word Document using mail merge and convert the code in to a Table when it is merged in word document. However when excel column in merged in Word Document the html code is not converted to Table and is shown as html code. Please help in this regard.

Observation_Heading	Observation_Content	Table
Documents not found in scanning Other Individual	While reviewing Account Opening Forms , it was noticed that following documents were not found while checking AOF’s and amendments.	<table> <tbody> <tr> <td> <p>Account Number</p> </td> <td> <p>Branch</p> </td> <td> <p>Account Title</p> </td> <td> <p>Opening Date</p> </td> <td> <p>Category</p> </td> <td> <p>Observations</p> </td> </tr> <tr> <td> <p>1006950357</p> </td> <td> <p>404</p> </td> <td> <p>Newtown Inc</p> </td> <td> <p>02/24/2020</p> </td> <td> <p>SA</p> </td> <td> <p>branch visit report not found while reviewing Account Opening form.</p> </td> </tr> <tr> <td> <p>5001181195</p> </td> <td> <p>5620</p> </td> <td> <p>ABC &amp; Compay</p> </td> <td> <p>11/19/2019</p> </td> <td> <p>CA</p> </td> <td> <p>S.S card not found while reviewing Account Opening form</p> </td> </tr> </tbody></table>

 

[navic]

This is my idea

1. Copy the HTML code to Notepad
2. Save as 'mycode.html' file
3. Open 'mycode.html' and select everything and then copy
4. Paste into an Excel file

You now have the data in the spreadsheet properly organized in Excel.
Further do what you want with the data.

 

[khawarameer]

Thank you @navic for your response however this is not what i want. Actually i want to pass the code from excel to word using mail merge and once code is in word then i want to covert it to table.

 

[John_w]

Here's an Excel macro you can build on. It reads the HTML table code from C2 on the active sheet and adds it as a table in a new Word document.

You must set the references noted at the top of the code, via Tools -> References in the VBA editor.

'References:
'Microsoft HTML Object Library
'Microsoft Word nn.0 Object Library

Public Sub Convert_HTML_Code_To_Word_Table()

    Dim HTMLdoc As HTMLDocument, HTMLdoc2 As HTMLDocument
    Dim table As HTMLTable
    Dim tRow As HTMLTableRow, tCell As HTMLTableCell
    Dim HTMLfile As String
    Dim wdApp As Word.Application
    Dim wdDoc As Word.document
    Dim wdTable As Word.table
    
    HTMLfile = Environ("temp") & "/table.html"
    Open HTMLfile For Output As #1
    Print #1, Range("C2").Value
    Close #1
    
    Set HTMLdoc2 = New HTMLDocument
    Set HTMLdoc = HTMLdoc2.createDocumentFromUrl(HTMLfile, "")
    While HTMLdoc.readyState <> "complete"
        DoEvents
    Wend
    Kill HTMLfile
    
    Set table = HTMLdoc.getElementsByTagName("TABLE")(0)
    
    Set wdApp = New Word.Application
    wdApp.Visible = True
    
    Set wdDoc = wdApp.Documents.Add
    Set wdTable = wdDoc.Tables.Add(Range:=wdDoc.Range, NumRows:=table.Rows.Length, NumColumns:=table.Rows(0).Cells.Length)
    wdTable.Borders.Enable = True
    
    For Each tRow In table.Rows
        For Each tCell In tRow.Cells
            wdTable.Cell(tRow.RowIndex + 1, tCell.cellIndex + 1).Range.Text = tCell.innerText
        Next
    Next
    
End Sub

 

[khawarameer]

@John_w Thank you sir. Your code is not the exact solution but it has given me a head start.