Converting dates

[kristell]

Can you please help me? I am having to daily download in CSV some information from a booking site. Unfortunately they are dates and times in USA format - so the 'days' are coming out in the middle. That isn't a big problem as I can change with the formatting, however - when I first download they look like this:

11/29/22 9:00 AM

11/29/22 9:00 AM

11/28/22 2:00 PM

11/21/22 2:00 PM

11/24/22 9:00 AM

11/24/22 9:00 AM

12/05/2022 14:00​

11/24/22 9:00 AM

12/05/2022 14:00​

11/21/22 2:00 PM

11/29/22 9:00 AM

12/01/2022 09:00​

11/23/22 2:00 PM

11/25/22 2:00 PM

11/29/22 9:00 AM

11/21/22 2:00 PM

11/21/22 2:00 PM

This is just a sample but there are around 600 rows

How can I get those on the right to change to be the same as those on the left - or vice versa?

I have tried using various formats - but it never works so they are all the same. I just need to be able to sort them, but it isn't working.

The ones on the left have come in as format 'General' and those on the left as Custom dd/mm/yyy hh:mm (which is wrong anyway as it is the month first). If I try changing those on the left to the same it makes no difference. If I change those on the right to General it changes to 44573.375. If I then try changing again to the date format it just goes back to what it was.

Am pulling my hair out - any ideas would be very much welcomed. If I could also convert all the dates/times to UK that would be an added bonus!

I am using a desktop version of Excel Microsoft® Excel® for Microsoft 365 MSO (Version 2209 Build 16.0.15629.20196) 32-bit

 

[Legacy 143009]

An overkill formula:

=TEXT(LEFT(A1,2)&"/"&MID(A1,4,2)&"/"&IF(FIND(" ",A1,5)-FIND("/",A1,5)=3,"20"&MID(A1,7,2),MID(A1,7,2)),"dd/mm/yyyy")&" "&TEXT(IF(RIGHT(A1,1)="M",IF(RIGHT(A1,2)="AM",TRIM(MID(A1,FIND(" ",A1,5),6)),MOD(12+INT(LEFT(TRIM(MID(A1,FIND(" ",A1,5),6)),2)),24)&RIGHT(TRIM(MID(A1,FIND(" ",A1,5),6)),3)),IF(LEN(TRIM(RIGHT(A1,6)))=5,0&TRIM(RIGHT(A1,6)),TRIM(RIGHT(A1,6)))),"hh:mm")

 

[steve the fish]

Heres another:

=IF(ISNUMBER(A1),DATE(YEAR(A1),DAY(A1),MONTH(A1))+MOD(A1,1),0+(MID(A1,4,3)&REPLACE(A1,3,3,"")))

 

[kristell]

=IF(ISNUMBER(A1),DATE(YEAR(A1),DAY(A1),MONTH(A1))+MOD(A1,1),0+(MID(A1,4,3)&REPLACE(A1,3,3,"")))

That has worked - amazing - thank you so much!

 

[kristell]

An overkill formula:

=TEXT(LEFT(A1,2)&"/"&MID(A1,4,2)&"/"&IF(FIND(" ",A1,5)-FIND("/",A1,5)=3,"20"&MID(A1,7,2),MID(A1,7,2)),"dd/mm/yyyy")&" "&TEXT(IF(RIGHT(A1,1)="M",IF(RIGHT(A1,2)="AM",TRIM(MID(A1,FIND(" ",A1,5),6)),MOD(12+INT(LEFT(TRIM(MID(A1,FIND(" ",A1,5),6)),2)),24)&RIGHT(TRIM(MID(A1,FIND(" ",A1,5),6)),3)),IF(LEN(TRIM(RIGHT(A1,6)))=5,0&TRIM(RIGHT(A1,6)),TRIM(RIGHT(A1,6)))),"hh:mm")

I went with the other one which was simpler but really appreciate your response