convert x and y to angle?

[Mutatis Mutandis]

Hi folks,
Long time lurker but never had an account.

I'm trying to convert x and y coordinates (both positive and negative) to an angle and distance for a mapping project. I can calculate the length no problem but the angle is bugging me?

The origin is always 0,0 in this case.

I need the angle to run clockwise with 0/360 degrees being the positive y axis and run clockwise around the graph?

For example
X1 in cell A1 is 0
Y1 in cell B1 is 0
X2 in cell A2 is 3.3
Y2 in cell B2 is -3.7

Length in C2 is SQRT((A2-A1)^2)+((SQRT(B2-B1)^2)) the answer for the above example is around 4.9

But how do I calculate the angle in say D2 as the angle can be in any of the 4 quadrants? The angle in the above example is around 140 degrees clockwise from the positive Y axis?

I've been trying to sort this out for days and finally give up, my math skills are no longer what they used to be when I was at college

Cheers,

MM

 

[KRice]

Try this...angle relative to line connecting the origin (0,0) to specified point with respect to the vertical y-axis being 0 and positive angles in a clockwise direction.

MrExcel_20220505B.xlsx
	A	B	C	D	E
1	0	0	<-- (x1, y1)	Length	Angle (degrees) wrt y axis=0 (clockwise +)
2	3.3	-3.7	<-- (x1, y1)	4.96	138.27
3	1	10	<-- (x1, y1)	10.05	5.71
4	1	-10	<-- (x1, y1)	10.05	174.29
5	-1	-10	<-- (x1, y1)	10.05	185.71
6	-1	10	<-- (x1, y1)	10.05	354.29
Sheet9

Cell Formulas
Range	Formula
D2	D2	=SQRT((A2-A1)^2+(B2-B1)^2)
E2:E6	E2	=IF(SIGN(A2)>=0,90-DEGREES(ATAN((B2)/(A2))),270-DEGREES(ATAN((B2)/(A2))))
D3:D6	D3	=SQRT((A3)^2+(B3)^2)

 

[BSALV]

x/y is tangens ...

 

[KenU]

For the angle formula in E2, you could use the following:

=MOD(DEGREES(ATAN2(B2,A2))+360,360)

The ATAN2 function will handle the signs to choose the right quadrant. The non-intuitive part is reversing the x and y coordinates to make the y-axis positive and reverse the positive angle direction. Adding 360 and using the MOD function with 360 as the divisor eliminates negative values.

Hope that helps.

Regards,
Ken

 

[KRice]

Nice idea, Ken.

 

[Mutatis Mutandis]

Thanks Ken for the speedy replies, that works well and I can now get on with the main task in hand.

MM