Confusing Code

[Kevin0427]

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)



'Plan Rejected
If Target.Column = 12 Then
ActiveSheet.Unprotect Password:="test"
Target.Offset(0, -6) = 0
'Target.Offset(0, 1) = Date + Time
Target = "þ"
'Range("b" & Target.Row & ":bz" & Target.Row).Locked = True
ActiveSheet.Protect Password:="test"
End If

I am confused by the following code. The two rows that you see as commented out do not run when they are uncommented. If I switch the two target.offset codes the first one always runs and the second one does not. The locked range used to work until I added the second offset and now it does not run even if bad code gets commented out.

 

[Snakehips]

Kevin, be more specific and use... Target.Value = "þ" and that should hopefully do it.

 

[Kevin0427]

Kevin, be more specific and use... Target.Value = "þ" and that should hopefully do it.

That line of code works. But I tried it anyway and no change.

 

[Fluff]

You're code works perfectly well for me.
Do you have any other Event code working on that sheet?

 

[Kevin0427]

Yes. Lots.

 

[Kevin0427]

Can I use this code?

target.row.locked = true

 

[Fluff]

In that case try

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
'Plan Rejected
   If Target.Column = 12 Then
      Cancel = True
      Application.EnableEvents = False
      ActiveSheet.Unprotect Password:="test"
      Target.Offset(0, -6) = 0
      Target.Offset(0, 1) = Date + Time
      Target = "þ"
      Range("b" & Target.Row & ":bz" & Target.Row).Locked = True
      ActiveSheet.Protect Password:="test"
   End If
   Application.EnableEvents = True
End Sub

 

[dmt32]

try this update

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)


    On Error GoTo exitsub
    Me.Unprotect Password:="test"
    
'Plan Rejected
    With Target
        If .Column = 12 Then
        Application.EnableEvents = False
        Cancel = True
            .Offset(0, -6).Value = 0
            .Offset(0, 1).Value = Now()
            .Value = "þ"
        End If
    End With
    Me.Range("b" & Target.Row).Resize(, 77).Locked = True
    
exitsub:
    Me.Protect Password:="test"
    Application.EnableEvents = True
End Sub

Dave

 

[Kevin0427]

That worked. Why do I not need those changes on all the other events?

 

[Kevin0427]

In that case try

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
'Plan Rejected
   If Target.Column = 12 Then
      Cancel = True
      Application.EnableEvents = False
      ActiveSheet.Unprotect Password:="test"
      Target.Offset(0, -6) = 0
      Target.Offset(0, 1) = Date + Time
      Target = "þ"
      Range("b" & Target.Row & ":bz" & Target.Row).Locked = True
      ActiveSheet.Protect Password:="test"
   End If
   Application.EnableEvents = True
End Sub

I meant to quote this. It worked. Why do I not need it in the rest of the event codes?