Conditional Formatting with VBA

[ERed1]

Hello all,

So in column M on sheet 1 I have data that is in no specific order and the amount is always chaning. The data is Dog, Cat, and Fish. On Sheet 2 starting in A1 going to A3, I have Dog, Cat, and Fish in their own columns. They each have a specific cell color and font color. I want there formatting from sheet 2 to go to the cells on sheet 1. Is there a way to do this with a VBA marco?

Thanks in advance.

 

[Fluff]

How about

Sub ERed1()
   Dim Cl As Range
   Dim Dic As Object
   
   Set Dic = CreateObject("scripting.dictionary")
   With Sheets("Sheet2")
      For Each Cl In .Range("A1", .Range("A" & Rows.Count).End(xlUp))
         Dic.Add Cl.Value, Array(Cl.Interior.Color, Cl.Font.Color)
      Next Cl
   End With
   With Sheets("Sheet1")
      For Each Cl In .Range("M2", .Range("M" & Rows.Count).End(xlUp))
         If Dic.exists(Cl.Value) Then
            Cl.Interior.Color = Dic.item(Cl.Value)(0)
            Cl.Font.Color = Dic.item(Cl.Value)(1)
         End If
      Next Cl
   End With
End Sub

 

[ERed1]

That did not work for me.

 

[Fluff]

It does for me

Care to supply some more information, rather than just

That did not work for me.

 

[ERed1]

It does for me

Care to supply some more information, rather than just

So when I changed it to my data it did not work. I then made another worksheet and tested everything and it worked fine. I was messing around with it I then copied my data over to the example worksheet so that nothing else could be interfering with it. Do the colors mater for the code? Does the character count matter? Or maybe does the character color mater? The all have to be black?

 

[Fluff]

The code takes the font & fill colour from the cells in sheet2 & applies them to the cells in sheet1 where the cell content matches. Like

Book1
	A
1	West Yorkshire
2	Derbyshire
3	Staffordshire
Sheet2

Book1
	M
1	County
2	Cumbria
3	Derbyshire
4	Derbyshire
5	West Yorkshire
6	Derbyshire
7	Derbyshire
8	West Yorkshire
9	Derbyshire
10	Staffordshire
11	Derbyshire
12	Derbyshire
13	Cheshire
14	West Yorkshire
15	West Yorkshire
16	West Yorkshire
17	Staffordshire
18	Somerset
19	Cumbria
20	Shropshire
Sheet1

 

[ERed1]

So on my sheet it isn't allowing the formatting to show. It shows a blank background until the button is pressed. After the button is pressed it pastes a white background instead of the correct color, but if the characters are cleared from the cell (ie fish) then the correct background color shows.

 

[ERed1]

I figured it out! My boss had it set as a conditional format. I undid that and it worked perfectly!

 

[ERed1]

Thanks for all of the help Fluff!

 

[Fluff]

Glad you sorted it out & thanks for the feedback.