Conditional format VBA based on other cells

[JSINISCALCHI]

I am trying to convert the following macro to a Worksheet (section change) format, but cannot figure out how to have the cells B87:M150 change based upon the text (red, green, white, amber, na) in O87150.


Sub ordinate()
Dim r As Range
For Each r In Range("o87150")

If r.Value = "RED" Then
r.EntireRow.Interior.ColorIndex = 3

ElseIf r.Value = "AMBER" Then
r.EntireRow.Interior.ColorIndex = 44

ElseIf r.Value = "WHITE" Then
r.EntireRow.Interior.ColorIndex = 2

ElseIf r.Value = "GREEN" Then
r.EntireRow.Interior.ColorIndex = 4

ElseIf r.Value = "NONE" Then
r.EntireRow.Interior.ColorIndex = 2

ElseIf r.Value = "NA" Then
r.EntireRow.Interior.ColorIndex = 15
End If
Next

Range("N86:IV132").Interior.ColorIndex = 2
Range("A86:A132").Interior.ColorIndex = 2
End Sub

 

[brian.wethington]

Something like this:

Option Compare Text
Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)

Dim mycolor As Long
If Intersect(Range("O87:O150"), Target) Is Nothing Or Target.Count > 1 Then Exit Sub
Select Case Target.Value
    Case "Red"
        mycolor = 3
    Case "Amber"
        mycolor = 44
    Case "White"
        mycolor = 2
    Case "Green"
        mycolor = 4
    Case "None"
        mycolor = 2
    Case "NA"
        mycolor = 15
End Select
Range(Cells(Target.Row, "B"), Cells(Target.Row, "M")).Interior.ColorIndex = mycolor

End Sub

Note, this will only change your rows as you make changes to the O column.

 

[JSINISCALCHI]

Works grest, except for formulas

Thanks,

The code works great when manually changing colors (typing the color into column O). I have the colors populate the cells based ona formula elsewhere in the spreadsheet and this code does not seem to update when the colors change.

 

[brian.wethington]

There are 2 ways this can be handled.... you can use a calculate event instead of change event or you can continue using the change event and change the ranges it is looking at to fit the ranges that if it is changed then the calculation will change.... right now the code will only make adjustments when the user changes O89 to O150.

 

[JSINISCALCHI]

fix

Is the fix to change the worksheet sub to

Private Sub Worksheet_Change(ByVal Target As Excel. Range)?

I did this and it did not work.

 

[brian.wethington]

What columns will change to force the O column changes?

Or you can set it up as a calculate event which will require some very different coding but is doable.

 

[JSINISCALCHI]

index cells

Thanks again for the help!

The index cells (initial calculation of color type based on conditional if statemenets) are in L7:L52. (I changed the intersect range to a smaller number of cells, O87:O132).

 

[JSINISCALCHI]

index cells

Thanks again for the help!

The index cells (initial calculation of color type based on conditional if statemenets) are in L7:L52. (I changed the intersect range to a smaller number of cells, O87:O132).

 

[brian.wethington]

Try replacing what I gave you before with something like this:

Option Compare Text
Option Explicit
Private Sub Worksheet_Calculate()

Dim mycolor As Long, Ce As Variant
For Each Ce In Range("O87:O132")
    Select Case Ce.Value
        Case "Red"
            mycolor = 3
        Case "Amber"
            mycolor = 44
        Case "White"
            mycolor = 2
        Case "Green"
            mycolor = 4
        Case "None"
            mycolor = 2
        Case "NA"
            mycolor = 15
        Case Else
            mycolor = 0
    End Select
    Range(Cells(Ce.Row, "B"), Cells(Ce.Row, "M")).Interior.ColorIndex = mycolor
Next Ce

End Sub

 

[JSINISCALCHI]

GREAT WORK

I appreciate the effort you gave this code. It beats using a trigger to activate my eariler macro!