Conditional copy and paste, then delete row

[dockingsched]

Hello all, Bit of an amateur trying to learn more on the use of Macros. Hoping for some assistance with this issue: I want to be able to search through my data to find rows where Column D displays "Negative".If it doesn't display "Negative", just move on to the next row. If it does display "Negative", i want to check if the value in Column A of this row is equal to the value in Column A of the previous row. I also want to check if the value in Column C of this row is equal to the value in Column C of the previous row. If either condition is not met, then just move on to the next row that displays "Negative". However, if both conditions are met, then I want to cut the values in Columns T through V of the row that displays "negative" and paste them onto Columns T through V of the previous row, then if possible delete the row that displays "Negative" where we just cut the values from. Hope I was able to explain that well enough and thank you for any assistance or guidance that can be provided.

 

[Fluff]

Hi & welcome to MrExcel.
A few questions
Does col D have the word Negative on it's own in a cell?
Can you ever have two consecutive rows with Negative in col D? If so what should happen?
Do cols T:V contain values or formulae?

 

[dockingsched]

Hi & welcome to MrExcel.
A few questions
Does col D have the word Negative on it's own in a cell?
Can you ever have two consecutive rows with Negative in col D? If so what should happen?
Do cols T:V contain values or formulae?

-Does col D have the word Negative on it's own in a cell?

Yes, the word Negative would be the only item inside the cell.

-Can you ever have two consecutive rows with Negative in col D? If so what should happen?

No, there won't be two consecutive rows with "Negative" in col D. Also, if the word negative is in the first row, it should just keep going to the next row since there's no previous row to compare data with.

-Do cols T:V contain values or formulas?

They contain numeric values, no formulas.

 

[Fluff]

Wrong

 

[Fluff]

Thanks for that, how about

Sub dockingsched()
    Dim Rng As Range, Cl As Range, DelRng As Range
    
    With Range("D2", Range("D" & Rows.Count).End(xlUp))
        .Replace "Negative", "=xxxNegative", xlWhole, , False, , False, False
        On Error Resume Next
        Set Rng = .SpecialCells(xlFormulas, xlErrors)
        On Error GoTo 0
        .Replace "=xxxNegative", "Negative", xlWhole, , False, , False, False
    End With
    If Rng Is Nothing Then MsgBox "No Negatives": Exit Sub
    For Each Cl In Rng
        If Cl.Offset(, -3) = Cl.Offset(-1, -3) And Cl.Offset(, -1) = Cl.Offset(-1, -1) Then
            Cl.Offset(-1, 16).Resize(, 3).Value = Cl.Offset(, 16).Resize(, 3).Value
            If DelRng Is Nothing Then Set DelRng = Cl Else Set DelRng = Union(DelRng, Cl)
        End If
    Next Cl
    If Not DelRng Is Nothing Then DelRng.EntireRow.Delete
End Sub

EDIT:
I removed the code from post#4 as it was wrong.

 

[dockingsched]

Thanks for that, how about

Sub dockingsched()
    Dim Rng As Range, Cl As Range, DelRng As Range
    
    With Range("D2", Range("D" & Rows.Count).End(xlUp))
        .Replace "Negative", "=xxxNegative", xlWhole, , False, , False, False
        On Error Resume Next
        Set Rng = .SpecialCells(xlFormulas, xlErrors)
        On Error GoTo 0
        .Replace "=xxxNegative", "Negative", xlWhole, , False, , False, False
    End With
    If Rng Is Nothing Then MsgBox "No Negatives": Exit Sub
    For Each Cl In Rng
        If Cl.Offset(, -3) = Cl.Offset(-1, -3) And Cl.Offset(, -1) = Cl.Offset(-1, -1) Then
            Cl.Offset(-1, 16).Resize(, 3).Value = Cl.Offset(, 16).Resize(, 3).Value
            If DelRng Is Nothing Then Set DelRng = Cl Else Set DelRng = Union(DelRng, Cl)
        End If
    Next Cl
    If Not DelRng Is Nothing Then DelRng.EntireRow.Delete
End Sub

EDIT:
I removed the code from post#4 as it was wrong.

this appears to be working perfectly, thanks a lot.

 

[Fluff]

You're welcome & thanks for the feedback