Concatenate codes for ref number semicolon delimited in row.

[wikus]

I have a reference number with multiple codes. I want to concatenate the codes semi colon delimited in column C next to first reference row.
Any help will be appreciated.

 

[etaf]

textjoin() and filter()
assuming they are always in order then
=IF(A1=A2,"",TEXTJOIN(";",,FILTER($B$2:$B$9,$A$2:$A$9=A2)))
otherwise a countIF maybe required

Book14
	A	B	C
1
2	a1	A1-1	A1-1;A1-2;A1-3
3	a1	A1-2
4	a1	A1-3
5	b5	B5-1	B5-1;B5-2
6	b5	B5-2
7	c3	C3-1	C3-1;C3-2;C3-3
8	c3	C3-2
9	c3	C3-3
Sheet1

Cell Formulas
Range	Formula
C2:C9	C2	=IF(A1=A2,"",TEXTJOIN(";",,FILTER($B$2:$B$9,$A$2:$A$9=A2)))

=IF(COUNTIF($A$2:A2,A2)>1,"",TEXTJOIN(";",,FILTER($B$2:$B$9,$A$2:$A$9=A2)))

Book14
	A	B	C
1
2	a1	A1-1	A1-1;A1-2;A1-3
3	a1	A1-2
4	a1	A1-3
5	b5	B5-1	B5-1;B5-2
6	b5	B5-2
7	c3	C3-1	C3-1;C3-2;C3-3
8	c3	C3-2
9	c3	C3-3
Sheet1

Cell Formulas
Range	Formula
C2:C9	C2	=IF(COUNTIF($A$2:A2,A2)>1,"",TEXTJOIN(";",,FILTER($B$2:$B$9,$A$2:$A$9=A2)))

 

[Fluff]

How about

=IF(COUNTIFS(A$2:A2,A2)=1,TEXTJOIN(";",,FILTER($B$2:$B$100,$A$2:$A$100=A2)),"")

 

[wikus]

This is prefect, thank you very much.

 

[wikus]

This is prefect, thank you very much.

 

[etaf]

you are welcome

 

[Fluff]

Glad we could help & thanks for the feedback.