CONCAT only if cell does NOT contain specific text

[lichldo]

I have the following CONCAT formula that works great - '=CONCAT(H5," ",I5," ",J5," ",K5," ",L5," $",M5)

However, I need it to become an IF forumula so that if H5 does NOT contain a "-" than this forumula will just give me the H5 value (as if the formula for this cell is just '=H5
but if the cell DOES contain a "-" than it does my above CONCAT forumula

is there a way to accomplish that?

 

[Fluff]

How about

=IF(H5="-",TEXTJOIN(" ",,H5:L5)&" $"&M5,H5)

 

[lichldo]

How about

=IF(H5="-",TEXTJOIN(" ",,H5:L5)&" $"&M5,H5)

That only returns the value in H5 whether there is a "-" or not when I apply to my sheet - not any values in I:M

 

[Fluff]

What sort of values do you have in H5?

 

[lichldo]

What sort of values do you have in H5?

I have names of project phases and roles in column H. So the phases would be something like "Creative Design" and roles would be something like " - Creative Senior -Art Direction"

So basically for the phases that do not have a "-" I just want to duplicate that value in the cell I am putting this IF/CONCAT forumula in to act as a header.
And for the roles that do have a "-" I want to CONCAT all of the data from H5:M5, adding in a $ before the value in M5

 

[Fluff]

Ok, how about

=IF(ISNUMBER(FIND("-",H5)),TEXTJOIN(" ",,H5:L5)&" $"&M5,H5)

 

[lichldo]

Ok, how about

=IF(ISNUMBER(FIND("-",H5)),TEXTJOIN(" ",,H5:L5)&" $"&M5,H5)

That works perfectly!!

Now that I can see if function, I wonder if it's possible to add 1 more condition?
can it add - If H5 contains "-" but I5 is blank, than do nothing/leave blank
but still if H5 contains "-" and I5 has any value, than CONCAT
and still if H5 does not contain "-" than just duplicate the value in H5

 

[Fluff]

Could I5 be blank & H5 not have a -

 

[lichldo]

Could I5 be blank & H5 not have a -

Ah yes, actually I5 would always be blank if H5 does not have a "-"

 

[Fluff]

Ok, how about

=IF(ISERROR(FIND("-",H5)),H5,IF(I5="","",TEXTJOIN(" ",,H5:L5)&" $"&M5))