Complex lookup problem

[phmalu]

The objective is to be able to find "Result1" and "Result2" (in this case columns P and Q) based on user input values for "case1" to "case6" (A to F). It's important to use all 6 input values because there are many cells with the same value. Finding the correct match is only possible this way.

Vlookup_test.xlsx
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1	case1	case2	case3	case4	case5	case6	Result1	Result2
2	1	2	2	1	2	7	rf071	jd022		All those are user input (fed into the formula)						Formula must find
3	1	3	2	4	4	0	rf067	jd099		case1	case2	case3	case4	case5	case6	Result1	Result2
4	2	5	5	2	1	3	rf070	jd028	E.g. 1	1	2	2	1	2	7	??	??
5	2	6	5	2	5	4	rf066	jd030	E.g. 2	5	2	8	1	8	7	Error	Error
6	3	1	2	5	0	9	rf056	jd031
7	3	1	4	5	0	9	rf056	jd057
8	4	2	1	3	3	5	rf038	jd026
9	4	2	1	3	3	7	rf072	jd026
10	5	2	9	1	8	7	rf071	jd043
Sheet1

Things to consider:
All columns can have one or more doubled values. However, once you combine all the input data from "case1" to "case6", the pair "Result1" and "Result2" will be unique.
If invalid data is inserted, an error must pop-up rather then use approximate match.

Thanks to all!

 

[Fluff]

How about

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1	case1	case2	case3	case4	case5	case6	Result1	Result2
2	1	2	2	1	2	7	rf071	jd022		All those are user input (fed into the formula)						Formula must find
3	1	3	2	4	4	0	rf067	jd099		case1	case2	case3	case4	case5	case6	Result1	Result2
4	2	5	5	2	1	3	rf070	jd028	E.g. 1	1	2	2	1	2	7	rf071	jd022
5	2	6	5	2	5	4	rf066	jd030	E.g. 2	5	2	8	1	8	7	Error	Error
6	3	1	2	5	0	9	rf056	jd031
7	3	1	4	5	0	9	rf056	jd057
8	4	2	1	3	3	5	rf038	jd026
9	4	2	1	3	3	7	rf072	jd026
10	5	2	9	1	8	7	rf071	jd043
11
Main

Cell Formulas
Range	Formula
P4:Q5	P4	=IFNA(INDEX(G$2:G$10,MATCH(1,($A$2:$A$10=$J4)*($B$2:$B$10=$K4)*($C$2:$C$10=$L4)*($D$2:$D$10=$M4)*($E$2:$E$10=$N4)*($F$2:$F$10=$O4),0)),"Error")
Press CTRL+SHIFT+ENTER to enter array formulas.

 

[phmalu]

How about

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L	M	N	O	P	Q
1	case1	case2	case3	case4	case5	case6	Result1	Result2
2	1	2	2	1	2	7	rf071	jd022		All those are user input (fed into the formula)						Formula must find
3	1	3	2	4	4	0	rf067	jd099		case1	case2	case3	case4	case5	case6	Result1	Result2
4	2	5	5	2	1	3	rf070	jd028	E.g. 1	1	2	2	1	2	7	rf071	jd022
5	2	6	5	2	5	4	rf066	jd030	E.g. 2	5	2	8	1	8	7	Error	Error
6	3	1	2	5	0	9	rf056	jd031
7	3	1	4	5	0	9	rf056	jd057
8	4	2	1	3	3	5	rf038	jd026
9	4	2	1	3	3	7	rf072	jd026
10	5	2	9	1	8	7	rf071	jd043
11
Main

Cell Formulas
Range	Formula
P4:Q5	P4	=IFNA(INDEX(G$2:G$10,MATCH(1,($A$2:$A$10=$J4)*($B$2:$B$10=$K4)*($C$2:$C$10=$L4)*($D$2:$D$10=$M4)*($E$2:$E$10=$N4)*($F$2:$F$10=$O4),0)),"Error")
Press CTRL+SHIFT+ENTER to enter array formulas.

I was able to solve the problem in a very sloppy way by combining all "case" cells so they become big unique numbers. Then I've used this auxiliary column to perform a reg VLOOKUP.
However, I must say your formula is a lot more elegant and easier to debug in the long run. Thank you so much, that's what I wanted in the first place but was unable to figure out on my own (big lookup formulas are always a bit troublesome).
10/10

 

[Fluff]

You're welcome & thanks for the feedback.