Compile error: Case Else outside Select Case

[Rufus Clupea]

I've looked up what the title of this post means, but (pardon the pun) that's not the Case. I must have done something else wrong, either syntactically or logically, but I can't see it.

The following Sub works fine until I try to insert the commented lines.

Private Sub TextBox1_Change()

    Dim i As Integer

    If Len(TextBox1.Value) = 1 Then Exit Sub
    
    If Val(TextBox1.Value) < SpinButton1.Min Then
        TextBox1.Value = SpinButton1.Min
    End If
    
    If Val(TextBox1.Value) > SpinButton1.Max Then
        TextBox1.Value = SpinButton1.Max
    End If
    
    SpinButton1.Value = TextBox1.Value
    Number1 = Val(TextBox1.Value)

Select Case Number1
    Case Is < 18
        Number1_Label1.Caption = "Minor"
       
    Case Is > 65
        Number1_Label1.Caption = "Senior"

[COLOR=#006400]'        For i = 1 To (Number1 - 65)
'            If ConditionA > Number1 Then Number1 = Number1 + 1:
'            If ConditionB > Number1 Then Number1 = Number1 + 2:
'            If ConditionC > Number1 Then Number1 = Number1 + 3:
'            If ConditionD > Number1 Then Number1 = Number1 + 4
'        Next i
'
'        If ConditionA < 1 Or ConditionB < 1 Or ConditionC < 1 Or ConditionD < Then
'            MsgBox "Text"[/COLOR]


    Case Else
        Number1_Label1.Caption = "Adult"
End Select
    
End Sub

Thanks.

 

[Norie]

You re missing an End If.

Private Sub TextBox1_Change()
Dim I As Long

    If Len(TextBox1.Value) = 1 Then Exit Sub

    If Val(TextBox1.Value) < SpinButton1.Min Then
        TextBox1.Value = SpinButton1.Min
    End If

    If Val(TextBox1.Value) > SpinButton1.Max Then
        TextBox1.Value = SpinButton1.Max
    End If

    SpinButton1.Value = TextBox1.Value
    Number1 = Val(TextBox1.Value)

    Select Case Number1
        Case Is < 18
            Number1_Label1.Caption = "Minor"

        Case Is > 65
            Number1_Label1.Caption = "Senior"

            For I = 1 To (Number1 - 65)
                If ConditionA > Number1 Then Number1 = Number1 + 1:
                If ConditionB > Number1 Then Number1 = Number1 + 2:
                If ConditionC > Number1 Then Number1 = Number1 + 3:
                If ConditionD > Number1 Then Number1 = Number1 + 4
            Next I

            If ConditionA < 1 Or ConditionB < 1 Or ConditionC < 1 Or ConditionD < 1 Then
                MsgBox "Text"
            End If

        Case Else
            Number1_Label1.Caption = "Adult"
    End Select

End Sub

 

[Rufus Clupea]

Thank you so much--that was it!

My last experience with BASIC was in the '80s on a C-64 (No such thing as an End-If). I still get confused when an End-If is/isn't required.

Back to the books... again!

 

[Fluff]

If you have a one line is like these

If k = 3 Then k = 23 Else k = 3

or
If k = 3 Then k = 23

or (with line continuations)
If k = 3 Then _
k = 23 Else _
k = 3

You do not need and End If, otherwise you do.

 

[Rufus Clupea]

IC.

I had to go back and check my original, because I thought I had originally written one of those (I did not).

Thank you,

 

[Fluff]

You're welcome