Compare two cells with conditional values and bold cell with greater than numerical value.

[Preacherman771]

I have a worksheet comprised of various cells with conditional formulas. What I would like to do is compare two of the cells, they have numerical values, and bold the one which is greater than the other one. On the attached
xl2bb copy, compare I8 & I9 and since in this moment, I9 is greater than, have the result of 31 Bolded. In the other, I16 & I17, bold I16.

NFL 2021 Standing.xlsx
	A	B	C	D	E	F	G	H	I	J	K
1
2
3			Games - Week		1
4
5
6			Thursday, 09/09	8:20pm	NBC		Raymond James Stadium
7
8			Cowboys					0-1-0	29
9			Buccaneers					1-0-0	31
10
11
12
13
14			Sunday, 09/12	1:00pm	CBS		FedEx Field
15
16			Chargers					1-0-0	20
17			Commanders					0-1-0	16
18
19
Week 1

Cell Formulas
Range	Formula
G6,G14	G6	=INDEX(TeamData[Stadium],MATCH(C9,TeamData[Team],0))
H8:H9,H16:H17	H8	=IF(C8<>"",INDEX(WeekData[Rec],MATCH(1,($E$3=WeekData[Wk'#])*(C8=WeekData[Team]),0)),"")
I8,I16	I8	=IF(C8<>"",INDEX(SchedData[ScoreA],MATCH(1,($E$3=SchedData[Wk'#])*(C8=SchedData[TeamA]),0)),"")
I9,I17	I9	=IF(C9<>"",INDEX(SchedData[ScoreH],MATCH(1,($E$3=SchedData[Wk'#])*(C9=SchedData[TeamH]),0)),"")
C8	C8	=INDEX(SchedData[TeamA],SMALL(IF(SchedData[Wk'#]=$E$3,IF(SchedData[Date]=C6,ROW(SchedData[Wk'#])-ROW(INDEX(SchedData[Wk'#],1,1))+1)),1))
C9	C9	=INDEX(SchedData[TeamH],SMALL(IF(SchedData[Wk'#]=$E$3,IF(SchedData[Date]=C6,ROW(SchedData[Wk'#])-ROW(INDEX(SchedData[Wk'#],1,1))+1)),1))
C16	C16	=INDEX(SchedData[TeamA],SMALL(IF(SchedData[Wk'#]=$E$3,IF(SchedData[Date]=C14,ROW(SchedData[Wk'#])-ROW(INDEX(SchedData[Wk'#],1,1))+1)),2))
C17	C17	=INDEX(SchedData[TeamH],SMALL(IF(SchedData[Wk'#]=$E$3,IF(SchedData[Date]=C14,ROW(SchedData[Wk'#])-ROW(INDEX(SchedData[Wk'#],1,1))+1)),2))
Press CTRL+SHIFT+ENTER to enter array formulas.

 

[Fluff]

Select I8 & I9 then in conditional formatting select new rule, use a formula & use

=I8=MAX(I$8:I$9)

 

[Preacherman771]

Thank you for your reply. It works greats.

 

[Fluff]

You're welcome & thanks for the feedback.