Compare individually the values from two different size ranges

[Mds1]

Hello!
Let’s say range1is a spilled range that contains 3 values. We have another range called range2 that is fixed and contains 5 elements.
I want to compare first value=20 from range1 with all the values from range2 and get first value that is greater or equal to 20. After this, go to the second value from range1 and compare and get a result. And so on.
How can I achieve this dynamically?
(Let’s say range1 can have more or less elements). Thank you in advance for the help!

Example:
Range1 Range2
20 15
30 20
40 30
45
60
Desired outcome:
20
30
45

 

[Cubist]

Shouldn't the last outcome be 30 since that's the first value greater or equal to 30? Why is it 45?
Secondly, you said you wanted "greater or equal to" since 20 is equal or greater than 20. The second result should be 20. Why 30?

 

[Mds1]

I tried to write in text, my bad.
I wanted to say:
Range1 = {20;30;40}
Range2 = {15;20;30;45;60}
To reduce the ambiguity,
Let it be:
Range1 = {1,2,3}
Range2 = {4,5,6}
In this case, for 1, 2 and 3 the result will be {4;4;4} because 4 in the first number greater than all of them.

 

[Cubist]

How about this?

Book1
	A	B	C	D	E
1	Range1	Range2		Answer
2	1	4		4
3	2	5
4	3	6
5
Sheet14

Cell Formulas
Range	Formula
A2:A4	A2	=SEQUENCE(3)
D2	D2	=XLOOKUP(TRUE,MAX(A2#)<B2:B4,B2:B4,,0,1)
Dynamic array formulas.

 

[Mds1]

I thought about it like this:

MSEPT_v1.1.xlsx
	A	B	C	D	E
1	A	B
2	20	15
3	30	30
4	40	45
5		60
6		75
7			Result:
8	i=1	1	30
9	i=2	2	30
10	i=3	3	45
11
12
Sheet3

Cell Formulas
Range	Formula
A2:A4	A2	=SEQUENCE(3,1,20,10)
B2:B6	B2	=SEQUENCE(5,1,15,15)
C8:C10	C8	=CHOOSEROWS(FILTER($B$2#,$B$2#>=IF(ISBLANK($B$2#),,CHOOSEROWS($A$2#,B8)),),1)
Dynamic array formulas.

The idea of this thread was if I can achieve a "spill" result, so that can be dinamically changed.
Thank you for your response!
But I changed my mind and I am using tables right now. Maybe this can be achieved somehow .

 

[Cubist]

Book1
	A	B	C
1	A	B
2	20	15	30
3	30	30	30
4	40	45	45
5		60
6		75
Sheet15

Cell Formulas
Range	Formula
A2:A4	A2	=SEQUENCE(3,1,20,10)
B2:B6	B2	=SEQUENCE(5,1,15,15)
C2:C4	C2	=BYROW(A2#,LAMBDA(r,XLOOKUP(TRUE,r<=B2#,B2#)))
Dynamic array formulas.

 

[Mds1]

This is so good. Everyday you learn something. Thank you very much! I'm new to lambda functions but I will get better.
I wish you all the best! Have a great day!

 

[Cubist]

Happy to help.