Compare and delete rows not matching

[ngocanh87]

Hi all,

I have code compare rows Result sheet & DLV030 sheet then delete row not matching but problem if at A2 (Result sheet) have only 1row, it will error at. Can help me fix this error. Thank all

d(itm) = 1

Sub save_as_file()
Dim d As Object
Dim a As Variant, b As Variant, itm As Variant
Dim nc As Long, i As Long, k As Long
Dim lastrow As Long
lastrow = Cells(Rows.Count, 2).End(xlUp).Row
Application.DisplayAlerts = False
Sheet1.Activate
Set d = CreateObject("Scripting.Dictionary")
a = Sheets("Result").Range("A2", Sheets("Result").Range("A" & Rows.Count).End(xlUp)).Value
For Each itm In a
d(itm) = 1
Next itm
With Sheets("DLV030")
a = .Range("AU2", .Range("AU" & Rows.Count).End(xlUp)).Value
ReDim b(1 To UBound(a), 1 To 1)
For i = 1 To UBound(a)
If Not d.exists(a(i, 1)) Then
k = k + 1
b(i, 1) = 1
End If
Next i
If k > 0 Then
Application.ScreenUpdating = False
nc = .Cells.Find(What:="*", LookIn:=xlFormulas, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column + 1
With .Range("A2").Resize(UBound(a), nc)
.Columns(nc).Value = b
.Sort Key1:=.Columns(nc), Order1:=xlAscending, Header:=xlNo
.Resize(k).EntireRow.Delete
End With
Application.ScreenUpdating = True
End If
End With
ActiveSheet.Cells(Rows.Count, "D").End(xlUp).EntireRow.Delete

End Sub

 

[DanteAmor]

Check the code that I updated in this thread:

vba Delete Row(s) not matching table criteria Macro

So i'll do my best to try and explain this. I have a spreadsheet with 2 tabs (DataExport; FilterCriteria) The DataExport tab is every computer i pulled from active directory (real long list) Column A is the PC name and Column B is the OU it resides in. The FilterCriteria tab Column A is a list...

www.mrexcel.com

I also put here the updated code to your sheets and your columns.

Sub Delete_Row_1()
  Dim arr As Variant, i As Long, j As Long, lr As Long
  Dim a As Variant, b As Variant, r As Range
  Dim sh1 As Worksheet, sh2 As Worksheet, exists As Boolean
 
  Application.ScreenUpdating = False
  '
  Set sh1 = Sheets("DLV030")
  Set sh2 = Sheets("Result")
  If sh1.AutoFilterMode Then sh1.AutoFilterMode = False
  lr = sh1.Range("AU" & Rows.Count).End(xlUp).Row
  a = sh1.Range("AU2:AU" & lr).Value2
  
  b = sh2.Range("A2:A" & sh2.Range("A" & Rows.Count).End(xlUp).Row + 1).Value
  Set r = sh1.Range("A" & lr + 1)
  For i = 1 To UBound(a)
    exists = False
    For j = 1 To UBound(b) - 1
      If a(i, 1) Like "*" & b(j, 1) & "*" Then
        exists = True
        Exit For
      End If
    Next
    If exists = False Then Set r = Union(r, sh1.Range("A" & i + 1))
  Next
  r.EntireRow.Delete
End Sub

The code works for 1 criteria or more criteria, but if you are always going to have one criteria, you only have to filter by data different from one criteria and delete, So, this is enough:

Sub Macro1()
  With Sheets("DLV030")
    .Range("AU1", .Range("AU" & Rows.Count).End(3)).AutoFilter 1, "<>" & Sheets("Result").Range("A2").Value
    .AutoFilter.Range.Offset(1).EntireRow.Delete
    .AutoFilterMode = False
  End With
End Sub

--------------
Let me know the result and I'll get back to you as soon as I can.
Sincerely
Dante Amor
--------------

 

[ngocanh87]

Thank you so much, it works perfectly.