ComboBox List from Range that selects a range until last row

[RawlinsCross]

So I have a userform that initializes with the following code. The comboboxes are named CB_AQUEOUS and CB_SOLDIS. I have ranges in Sheet1 that I source the lists from. But if the ranges change, I have to manually update the code. Is there a way I can simply do a *last row* on this? Is the fact that this is in an initialization routine problematic?

Private Sub UserForm_Initialize()

Me.DTPicker1 = Date - 190
Me.DTPicker2 = Date

'This is the code I want to look at.
CB_AQUEOUS.List = Worksheets("Sheet1").Range("A2:A36").Value
CB_SOLIDS.List = Worksheets("Sheet1").Range("B2:B11").Value
CB_AQUEOUS.Value = "---Please Select---"
CB_SOLIDS.Value = "---Please Select---"


Set mwksWorksheet = wWorksheetPVar
msICP = sSamplePVar
msICP = sICPPVar & sSamplePVar
Call PopulateControlArrays
Call MonthButtonColor
Call SetSummary
End Sub

 

[Fluff]

How about

With Worksheets("Sheet1")
   CB_AQUEOUS.List = .Range("A2", Range("A" & Rows.Count).End(xlUp)).Value
   CB_SOLIDS.List = .Range("B2", .Range("B" & Rows.Count).End(xlUp)).Value
End With
CB_AQUEOUS.Value = "---Please Select---"
CB_SOLIDS.Value = "---Please Select---"

 

[RawlinsCross]

Good day, tried that code and I'm getting a "Run-time error '1004' Application-defined or object-defined error"

 

[Fluff]

Which line of code returned the error?

 

[mikerickson]

Perhaps

Private Sub UserForm_Initialize()

Me.DTPicker1 = Date - 190
Me.DTPicker2 = Date

'This is the code I want to look at.
With Worksheets("Sheet1")
    With Range("A:A")
        CB_AQUEOUS.List = Range((.Cells(2,1), .Cells(Rows.Count,1).End(xlup)).Value
    End With
    With Range("B:B")
        CB_SOLIDS.List = Range((.Cells(2,1), .Cells(Rows.Count,1).End(xlup)).Value
    End With
End With

'...
End Sub

 

[RawlinsCross]

@Fluff
The code is failing at

CB_AQUEOUS.List = .Range("A2", Range("A" & Rows.Count).End(xlUp)).Value

@Mike
Your code runs but I had to remove the first bracket (code font was red indicating syntax error). But it seems it's grabbing the range not from "Sheet" one but from another sheet where the userform is launched.

 

[Fluff]

Oops, I missed a . before the 2nd Range. It should be

CB_AQUEOUS.List = .Range("A2", [COLOR=#ff0000].[/COLOR]Range("A" & Rows.Count).End(xlUp)).Value

 

[RawlinsCross]

Yes, that worked... @Mike - curious as to why your code is pulling from another Worksheet.
@Fluff - How does the rows.count know which column it's dealing with (in my sheet column A and B have different counts)

 

[Fluff]

Rows.Count, simply counts the number of available rows in the sheet. So these days that's 1048576, but when using an xls file it's only 65536

Mike made the same mistake as me

With Worksheets("Sheet1")
    With [COLOR=#ff0000].[/COLOR]Range("A:A")
        CB_AQUEOUS.List = Range(.Cells(2,1), .Cells(Rows.Count,1).End(xlup)).Value
    End With
    With [COLOR=#ff0000].[/COLOR]Range("B:B")
        CB_SOLIDS.List = Range(.Cells(2,1), .Cells(Rows.Count,1).End(xlup)).Value
    End With
End With

 

[RawlinsCross]

Right, that clears up some confusion - I was thinking 'wouldn't it be xldown?' Anyhow, good lesson here. Cheers!