Combobox duplicate validation

[MFish]

Hi there,

I have two comboboxes that will NEED to go into two separate columns. I need the code to run if the two comboboxes have both been picked exactly the same on the sheet before moving forward... I tried writing this code and it doesn't work with concatenating.

Range("B7:C7").Select
        'Check for duplicate bill name
Do Until UCase(ActiveCell) = UCase(cmbLH) & UCase(cmbLeg) Or ActiveCell = ""
        ActiveCell.Offset(1, 0).Select
Loop

If ActiveCell <> "" Then
        MsgBox "" & cmbLH & cmbLeg & " already exists in the Table. Please choose a different Line Haul Number", _
    vbOKOnly, "Duplicate Line Haul Number detected"
    frmAdd.Show
Exit Sub

Else: End If

Any thoughts on how I can run a duplicate validation on two cells next to eachother and if those match what I just have in the two comboboxes?

 

[DanteAmor]

Try this

Private Sub CommandButton1_Click()
    'Validation
    Dim r As Range, f As Range, cell As String
    
    If cmbLH.ListIndex = -1 Or cmbLeg.ListIndex = -1 Then
        MsgBox "Select data"
        Exit Sub
    End If
    
    Set r = Range("B2", Range("B" & Rows.Count).End(xlUp))
    Set f = r.Find(cmbLH.Value, LookIn:=xlValues, lookat:=xlWhole)
    If Not f Is Nothing Then
        cell = f.Address
        Do
            If f.Offset(, 1).Value = cmbLeg.Value Then
                MsgBox "" & cmbLH & " " & cmbLeg & ", already exists in the Table. " & _
                    "Please choose a different Line Haul Number", _
                    vbOKOnly, "Duplicate Line Haul Number detected"
            End If
            Set f = r.FindNext(f)
        Loop While Not f Is Nothing And f.Address <> cell
    End If
End Sub