ComboBox and Showing Data

[mharper90]

I'm trying to take the data from column "C" (excluding the header) on sheet "Health Form Corrections" and display it into "ComboBox1" on "UserForm1" without any duplicates in the combo box.

From that combo box I want to hit "Submit" and have it display all of the data that matches the combo box selection from sheet "Health Form Corrections" onto "Sheet3" (anywhere is ok for now).

I have never figured out how to display data, period. But now I'm also trying to get a combo box without duplicates. Any help is greatly appreciated! Thanks!

 

[AlphaFrog]

Private Sub UserForm_Initialize()
    
    Dim rngUniques As Range, cell As Range
    
    'Filter column C for unique values
    Application.ScreenUpdating = False
    With Sheets("Health Form Corrections")
        If .FilterMode Then .ShowAllData
        .Range("C1", .Range("C" & Rows.Count).End(xlUp)).AdvancedFilter Action:=xlFilterInPlace, Unique:=True
        Set rngUniques = .Range("C2", .Range("C" & Rows.Count).End(xlUp)).SpecialCells(xlCellTypeVisible)
        If .FilterMode Then .ShowAllData
    End With
    Application.ScreenUpdating = True
    
    'Populate combobox from rngUniques
    For Each cell In rngUniques
        ComboBox1.AddItem cell.Value
    Next cell
End Sub
    
    
Private Sub CommandButton1_Click()
    'Submit button
    'Copy filtered data
    If ComboBox1.ListIndex > -1 Then
        Application.ScreenUpdating = False
        With Sheets("Health Form Corrections")
            With .Range("C1", .Range("C" & Rows.Count).End(xlUp))
                .AutoFilter 1, ComboBox1.Value
                .Offset(1).EntireRow.Copy Destination:=Sheets("Sheet3").Range("A1")
            End With
            .AutoFilterMode = False
        End With
        Application.Goto Sheets("Sheet3").Range("A1")
        Application.ScreenUpdating = True
    Else
        MsgBox "Nothing selected in combobox. ", vbExclamation, "Invalid Entry"
    End If
End Sub