Combining Sumproduct with Vlookup

[jlogan223]

Hi All,

I am new to this forum, I have done a search but can not see any posts with the same issue, so here goes.

I have multiple documents each with 45+ sheets, 38 of which I need to get data from, I can not edit these sheets but I can add an additional one (summary Page). What I am trying to do is combine a Vlookup and a sum product in to a single cell on a summary page, If there are any easier ways of doing this please feel free to make a suggestion.

My Data:

Row/Column	I	AB	AC	AD	AE	AK
	Part	Currency	Type 1 Price	Type 2 Price	Type 3 Price	Quantity required
20	a	GBP	1.50	3	6.25	1
21	ab	EUR	4	1	0.5	2
22	b	USD	3.30	3.30	7	1
23	cg	GBP	12.90	100	156	0
24	ef	GBP	0.90	0.85	12	4
..	..	..	..	..	..	..
..	..	..	..	..	..	..
..	..	..	..	..	..	..
100	..	..	..	..	..	..

<tbody>
</tbody>

What I need to be able to do is have one cell in a summary page that sum the following up:

What I need is a single formula for Type 1 price per sheet, so I need to do is:

multiple the quantity * the unit price *the currency (which needs to be looked up in another sheet),
then give me a sum for the complete sheet for Type 1 price in a single cell on a summary page, then the same for Type 2 and Type 3

so something like (but not) this:

Sumproduct=((AK20:AK100),AC20:AC100),Vlookup(AB20:AB100,'LOOKUPSHEET'!A1:B40,2,FALSE))

I hope this makes sense, If I have missed anything out please let me know.

Thanks,
Justin

 

[Domenic]

Assuming that each currency that occurs in Column AB is listed in the lookup table, try...

=SUMPRODUCT(AK20:AK100,AC20:AC100,SUMIF(LOOKUPSHEET!A1:A40,AB20:AB100,LOOKUPSHEET!B1:B40))

Hope this helps!

 

[jlogan223]

Assuming that each currency that occurs in Column AB is listed in the lookup table, try...

=SUMPRODUCT(AK20:AK100,AC20:AC100,SUMIF(LOOKUPSHEET!A1:A40,AB20:AB100,LOOKUPSHEET!B1:B40))

Hope this helps!

Thanks Domenic, That is almost exactly what I am looking for. I have however identified one issue, if the Currency appears more than once in the lookup table, it adds the conversation rates together, ie:

Country	Currency Code	Conversion rate
Germany	EUR	0.833
Great Britain	GBP	1
United States	USD	0.571
France	EUR	0.833

<tbody>
</tbody>

This would then give me a multiplier of 1.66666, is there anyway around this, so that it finds the EUR value then just takes that one value instead of finding the rest and adding them up?

Regards,
Justin

 

[Domenic]

In that case, try...

=SUMPRODUCT(AK20:AK100,AC20:AC100,SUMIF(LOOKUPSHEET!A1:A40,AB20:AB100,LOOKUPSHEET!B1:B40)/COUNTIF(LOOKUPSHEET!A1:A40,AB20:AB100))

However, if you sort your lookup table by currency and in ascending order, the LOOKUP function can be used instead of SUMIF/COUNTIF. Using LOOKUP should be more efficient. So, for example, sort your lookup table as follows...

Country	Currency Code	Conversion rate
France	EUR	0.833
Germany	EUR	0.833
Great Britain	GBP	1
United States	USD	0.571

<tbody>
</tbody>

Then, if each item that occurs in Column AB is listed in the lookup table, try...

=SUMPRODUCT(AK20:AK100,AC20:AC100,LOOKUP(AB20:AB100,LOOKUPSHEET!B1:C40))

Otherwise, try...

=SUM(IF(ISNUMBER(MATCH(AB20:AB100,LOOKUPSHEET!B1:B40,0)),(AK20:AK100)*(AC20:AC100)*(LOOKUP(AB20:AB100,LOOKUPSHEET!B1:C40))))

...which needs to be confirmed with CONTROL+SHIFT+ENTER.

Hope this helps!