Combined IF/OR statement with the OR based on a group of values in cells

[gberg]

I am trying to come up with a formula that I won't have to list out each specific value for all of the "OR"s

I have a list of "Fuel Categories" that I want to reference but not individual values. They are in Cells V2 to V16

Fuel Categories

7-ELEVEN

BPPRODUCTS

EXXONMOBIL

SHEETZ

SHELL

SUNOCO

UNBRANDED

UNKNOWN

WAWA

Future Station

Future Station

Future Station

Future Station

Future Station

Future Station

This is the formula I have

=IF(OR(COUNTIF([@[Item/Service Description]],"*"&$V$2&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$3&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$4&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$5&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$6&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$7&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$8&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$9&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$10&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$11&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$12&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$13&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$14&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$15&"*"),COUNTIF([@[Item/Service Description]],"*"&$V$16&"*")),"Fuel","")

I wanted something like this but just don't know how to make it work

=IF(OR([@[Item/Service Description]]="*"&$V$2:$V$16&"*"),"Fuel","")

 

[Fluff]

How about

=IF(SUM(COUNTIFS([@[Item/Service Description]],"*"&$V$2:$V$16&"*")),"Fuel","")

 

[Vogateer]

Maybe something like this?

=IF((SUM(--ISNUMBER(SEARCH($V$3:$V$17, [@[Item/Service Description]]))))>0, "Fuel","")

EDIT:
Looks like Fluff beat me to it, and Fluff usually catches edge cases that I miss, so I'd go with the previous answer.

 

[gberg]

They both work, wish I could check both of them as the correct answer. There are amazing people on this board! Thanks for your help!

 

[Fluff]

Glad we could help & thanks for the feedback.