Code to insert current date and time when a value is enter into column B

[Offroadracer_814]

Hello,

Thanks for taking you time to read my problem. I am tracking my blood pressure. With Column A being current date and time (m/d/yy h:m AM/PM).

What I envision is once I but the first number into column B. That a code would insert the current date and time. Then make my active cell as column C to enter the next number.

I found this code on the internet. But, I can not figure out the offset correctly. Plus, I know I have to change the Target Column to 2. But, it is kicking my backside.

'Code by Sumit Bansal from https://trumpexcel.com
Private Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo Handler
If Target.Column = 1 And Target.Value <> "" Then
Application.EnableEvents = False
Target.Offset(0, 1) = Format(Now(), "dd-mm-yyyy hh:mm:ss")
Application.EnableEvents = True
End If
Handler:
End Sub'Code by Sumit Bansal from https://trumpexcel.com

Any help would be appreciated.

Thanks

Kevin

 

[sadboy309]

Code for insert to Column Next

[COLOR=#333333]Private Sub Worksheet_Change(ByVal Target As Range)
[/COLOR]Static i As Integer
[COLOR=#333333]On Error GoTo Handler[/COLOR]
[COLOR=#333333]If Target.Column = 1 And Target.Value <> "" Then[/COLOR]
[COLOR=#333333]Application.EnableEvents = False
[/COLOR]
For i = 1 to 200
If Target.Offset(0, i) <> "" Then Exit For
Next

[COLOR=#333333]Target.Offset(0, i) = Format(Now(), "dd-mm-yyyy hh:mm:ss")[/COLOR]
[COLOR=#333333]
Application.EnableEvents = True[/COLOR]
[COLOR=#333333]End If[/COLOR]
[COLOR=#333333]Handler:[/COLOR]
[COLOR=#333333]End Sub[/COLOR]

 

[footoo]

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count <> 1 Then Exit Sub
Application.EnableEvents = False
If Target.Column = 2 Then
    If Target.Value = "" Then
        Target(1, 0).ClearContents
    Else
        Target(1, 0) = Format(Now(), "dd-mm-yyyy hh:mm:ss")
        Target(1, 2).Select
    End If
ElseIf Target.Column = 3 Then Target(2, 0).Select
End If
Application.EnableEvents = True
End Sub

 

[JoeMo]

This version will undo copy/paste to multiple col B cells at a time and clear date/time from col A if user wants to delete a prior col B entry.

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Columns("B")) Is Nothing Then
    If Target.Count = 1 Then
        If Target.Value <> "" Then
            Application.EnableEvents = False
            Target.Offset(0, -1).Value = Now
            Target.Offset(0, 1).Select
            Application.EnableEvents = True
            Exit Sub
        Else
            If Not IsEmpty(Target.Offset(0, -1)) Then
                Application.EnableEvents = False
                Target.Offset(0, -1) = ""
                Target.Offset(0, 1).Select
                Application.EnableEvents = True
                Exit Sub
            End If
        End If
    End If
    MsgBox "Confine column B entries to one cell per entry"
    With Application
        .EnableEvents = False
        .Undo
        .EnableEvents = True
        Exit Sub
    End With
End If
End Sub

 

[Offroadracer_814]

Thank you all!