Code to Disregard VBA or to Execute if Condition Met

[VinceF]

Greetings,
Hopefully this is an easy one for the experts.

If on sheet "MAIN" in cell C3 the selection from a DDL = SKINS I'd like the code for the VinE Cup to do nothing.
or
If on the MAIN sheet cell C3 = QUOTA & SKINS or QUOTA the code would be executed.

Whichever is easiest as either way should work.

Thanks for your assistance,
VinceF
Win10
Excel 2016




Sub COPY_AND_PASTE()
Dim n As Long
Application.ScreenUpdating = False
n = Sheets("MAIN").Range("AA3").Value

With Sheets("WIN").Cells(2, 4 + n).Resize(143)
.Copy
.PasteSpecial xlPasteValues
Application.CutCopyMode = False
Sheets("WIN").Select
Range("C5").Select
Sheets("MAIN").Select

Dim myCell As Range

Application.ScreenUpdating = False

For Each myCell In Sheets("SCORING HISTORY").Range("F5:AS141").SpecialCells(xlCellTypeFormulas, 1)
myCell.Copy
myCell.PasteSpecial xlValues
Next


With Application
.CutCopyMode = False
.ScreenUpdating = True

For Each myCell In Sheets("VinE CUP").Range("F8:AS144").SpecialCells(xlCellTypeFormulas, 1)
myCell.Copy
myCell.PasteSpecial xlValues
Next

With Application
.CutCopyMode = False
.ScreenUpdating = True

End With
Sheets("MAIN").Select
End With

End With

End Sub

 

[Alex Blakenburg]

See if this heads you in the right direction.
Note: As it stands the If statement looking for QUOTE etc is case sensitive.

Sub COPY_AND_PASTE()
    Dim n As Long
    Application.ScreenUpdating = False
    n = Sheets("MAIN").Range("AA3").Value
    
    With Sheets("WIN").Cells(2, 4 + n).Resize(143)
        .Value = .Value
    End With
        
    Dim myCell As Range
    
    For Each myCell In Sheets("SCORING HISTORY").Range("F5:AS141").SpecialCells(xlCellTypeFormulas, 1)
        With myCell
            .Value = .Value
        End With
    Next myCell
    
    If Sheets("MAIN").Range("C3").Value = "QUOTA & SKINS" _
        Or Sheets("MAIN").Range("C3").Value = "QUOTA" Then
            For Each myCell In Sheets("VinE CUP").Range("F8:AS144").SpecialCells(xlCellTypeFormulas, 1)
                With myCell
                    .Value = .Value
                End With
            Next myCell
    End If
    
    Application.ScreenUpdating = True
    Sheets("MAIN").Select

End Sub

 

[VinceF]

Thank you Alex, very much appreciated......working perfectly...

VinceF

 

[Alex Blakenburg]

Thanks for letting me know. Glad I could help.