Choose the site to save the PDF file

[KhallP]

The following code I created is to save the Excel sheet PDF file in a specific folder with a specific filename according to the value of the variables

Dim FilePath As String

    Select Case MachineName
    
    Case "A4", "A8.1", "A8.2", "A8.3", "A12.1", "A12.2", "A12.3", "A20.1", "A20.2"
         FilePath = Environ("userprofile") & "\Documents\Projeto\" & MachineName & "\"

    Sheets("Miter_Registers").Range("A1:AK29").ExportAsFixedFormat Type:=xlTypePDF, Filename:=FilePath & "Miter" & " _ " & MachineName & " _ " & Format(Now(), "dd.mm.yyyy") & " _ " & Format(Now(), "hh.mm") & " _ " & ".pdf" _
     , Quality:=xlQualityStandard, IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, OpenAfterPublish:=False
     End Select
End Sub

I would like to know if it is possible to change the code so that the user could save the file in the desired place (such as when downloading an image from the internet) without specifying it beforehand but keeping the file name according to the variable ("MachineName" )

 

[Trixterz]

Try things and let me know if it works...

    Dim Counter As Integer, FindFileType As Integer, SaveAsFileName As String
    
    Select Case MachineName
        Case "A4", "A8.1", "A8.2", "A8.3", "A12.1", "A12.2", "A12.3", "A20.1", "A20.2"
        SaveAsFileName = "Miter" & " _ " & MachineName & " _ " & Format(Now(), "dd.mm.yyyy") & " _ " & Format(Now(), "hh.mm") & " _ "
        
        With Application.FileDialog(msoFileDialogSaveAs)
            FindFileType = 0
            For Counter = 1 To .Filters.Count
                If InStr(VBA.UCase(.Filters(Counter).Description), "PDF") > 0 Then FindFileType = Counter
            Next
    
            .Title = "Save File As PDF"
            .InitialFileName = SaveAsFileName
            .FilterIndex = FindFileType
            
            If .Show Then
                ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:=.SelectedItems(1), _
                    Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            End If
        End With
    End Select

 

[KhallP]

Try things and let me know if it works...

    Dim Counter As Integer, FindFileType As Integer, SaveAsFileName As String
   
    Select Case MachineName
        Case "A4", "A8.1", "A8.2", "A8.3", "A12.1", "A12.2", "A12.3", "A20.1", "A20.2"
        SaveAsFileName = "Miter" & " _ " & MachineName & " _ " & Format(Now(), "dd.mm.yyyy") & " _ " & Format(Now(), "hh.mm") & " _ "
       
        With Application.FileDialog(msoFileDialogSaveAs)
            FindFileType = 0
            For Counter = 1 To .Filters.Count
                If InStr(VBA.UCase(.Filters(Counter).Description), "PDF") > 0 Then FindFileType = Counter
            Next
   
            .Title = "Save File As PDF"
            .InitialFileName = SaveAsFileName
            .FilterIndex = FindFileType
           
            If .Show Then
                ActiveWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:=.SelectedItems(1), _
                    Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            End If
        End With
    End Select

Your code is close but I just need to export to PDF the sheet ("Miter") with range ("A1:AK29"), could you help me?

 

[Trixterz]

Oops my bad... forgot to include the last part..

    Dim Counter As Integer, FindFileType As Integer, SaveAsFileName As String
    
    Select Case MachineName
        Case "A4", "A8.1", "A8.2", "A8.3", "A12.1", "A12.2", "A12.3", "A20.1", "A20.2"
        SaveAsFileName = "Miter" & " _ " & MachineName & " _ " & Format(Now(), "dd.mm.yyyy") & " _ " & Format(Now(), "hh.mm") & " _ "
        
        With Application.FileDialog(msoFileDialogSaveAs)
            FindFileType = 0
            For Counter = 1 To .Filters.Count
                If InStr(VBA.UCase(.Filters(Counter).Description), "PDF") > 0 Then FindFileType = Counter
            Next
    
            .Title = "Save File As PDF"
            .InitialFileName = SaveAsFileName
            .FilterIndex = FindFileType
            
            If .Show Then
                ActiveWorkbook.Sheets("Miter_Registers").Range("A1:AK29").ExportAsFixedFormat Type:=xlTypePDF, Filename:=.SelectedItems(1), _
                    Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
            End If
        End With
    End Select