Check if a cell content has a match in a folder and if yes add a designator to corresponding cell

[zakasnak]

Hello, all!

It's been awhile since I've posted, but this one is challenging me.

I have a sheet with unique values for documents in column A, 10 char, header row 1. I would like to run a search on a network folder (S:\_FY2024) to see if the document has already been processed at least once (sometimes they can be processed more than once), which would show up as the unique value at the beginning of the file name. If the document number is found in the file directory, I would like for the macro to put a designator "Y" in the same row, col K.

Document	Organization	Traveler	TANUM	Trip Name	Trip End	Total Cost	Days Waiting	Assigned?		Returned?
TV0001XXXX	ORGORG	Lname, Fname	TANUM0001XXXX	Trip Name	4/26/2024	$555.50	22​	TM

I assume it will need to be VBA, but if a formula would work, I would be happy with that as well! :D

TIA for any help anyone can give me!

 

[eiloken]

try:

Option Explicit

Sub LoopThroughFilesInFolder()
    Application.ScreenUpdating = False
    Dim xDir As String, xName As String
    Dim xFSO As Object, xFolder As Object, xFile As Object
    Dim i As Long
    Dim iList As Range, cll As Range
    i = lr(ThisWorkbook.Sheets(1), 1)
    If i < 2 Then Exit Sub
    Set iList = ThisWorkbook.Sheets(1).Cells(2, 1).Resize(i - 1, 1)
    xDir = "S:\_FY2024"
    Set xFSO = CreateObject("Scripting.FileSystemObject")
    Set xFolder = xFSO.GetFolder(xDir)
    For Each xFile In xFolder.Files
        xName = xFSO.GetFileName(xFile)
        Set cll = Nothing
        Set cll = iList.Find(What:=Left(xName, 10), LookIn:=xlValues, LookAt:=xlWhole)
        If Not cll Is Nothing Then cll.Offset(, 10).Value = "Y"
        Application.StatusBar = "Comparing: " & xName
        DoEvents
    Next xFile
    Application.StatusBar = False
    Set xFile = Nothing
    Set xFolder = Nothing
    Set xFSO = Nothing
    Application.ScreenUpdating = True
End Sub

Private Function lr(ByVal ws As Worksheet, ByVal icol As Integer) As Long
    lr = ws.Cells(Rows.Count, icol).End(xlUp).Row
End Function