Check for duplicates

[NDMDRB]

Hello,

I have a userform with 8 textboxes (txt_Name1, txt_Name2...txt_Name8)

I'm trying to add a piece of code to check the textboxes above if any name is duplicate, I tried the following code but didn't work

Can you please help me?


Code:
Private Sub cmd_Add_Clich()
Dim i As Long
For i = 1 To cmb_Num.value 'cmb_Num is a list (1 to 8)
If Me.Controls("txt_Name" & i) = Me.Controls("txt_Name" & i) Then
Me.lbl_Alert.Caption = "The name of User " & i & " is already exist!!!"
Me.Controls("txt_Name" & i).SetFocus
Exit Sub
End If
Next i

 

[Fluff]

How about

Private Sub cmd_Add_Clich()
    Dim i As Long
    With CreateObject("scripting.dictionary")
        For i = 1 To cmb_Num.Value 'cmb_Num is a list (1 to 8)
            If .exists(Me.Controls("txt_Name" & i).Value) Then
                Me.lbl_Alert.Caption = "The name of User " & i & " is already exist!!!"
                Me.Controls("txt_Name" & i).SetFocus
                Exit Sub
            ElseIf Me.Controls("txt_Name" & i) <> "" Then
                .Add Me.Controls("txt_Name" & i).Value, Nothing
            End If
        Next i
    End With
End Sub

 

[NDMDRB]

Amazing, thank you so much Fluff

 

[Fluff]

If you want to add the check for empty text boxes, you can do it like

Private Sub cmd_Add_Clich()
    Dim i As Long
    With CreateObject("scripting.dictionary")
        [COLOR=#ff0000].CompareMode = 1[/COLOR]
        For i = 1 To cmb_Num.Value 'cmb_Num is a list (1 to 8)
            If Me.Controls("txt_Name" & i) = "" Then
                Me.lbl_Alert.Caption = "The name field for User" & i & "is empty"
                Me.Controls("txt_Name" & i).SetFocus
                Exit Sub
            ElseIf .exists(Me.Controls("txt_Name" & i).Value) Then
                Me.lbl_Alert.Caption = "The name of User " & i & " is already exist!!!"
                Me.Controls("txt_Name" & i).SetFocus
                Exit Sub
            Else
                .Add Me.Controls("txt_Name" & i).Value, Nothing
            End If
        Next i
    End With
End Sub

The part in red makes it case insensitive, if it needs to be case sensitive just remove it.