Character removal

[Deelof]

What's the best formula to use if I want to remove "-OLS / -BCLCIRCS / -C" from the end of the below codes?
Leaving BS00008-3 / CF00021-2 / BF00027-9

BS00008-3-OLS

CF00021-2-BCLCIRCS

BF00027-9-C

 

[hagia_sofia]

If there are only 2 hyphens in all your data you could e.g. try:

=LEFT(A1,SEARCH("|",SUBSTITUTE(A1,"-","|",2))-1)

 

[Deelof]

If there are only 2 hyphens in all your data you could e.g. try:

=LEFT(A1,SEARCH("|",SUBSTITUTE(A1,"-","|",2))-1)

Amazing, thank you that's worked a treat!

 

[Peter_SSs]

If your sample data is representative then you could just use this.

24 07 29.xlsm
	A	B
1	BS00008-3-OLS	BS00008-3
2	CF00021-2-BCLCIRCS	CF00021-2
3	BF00027-9-C	BF00027-9
Deelof

Cell Formulas
Range	Formula
B1:B3	B1	=LEFT(A1,9)

 

[felixstraube]

Another option:

Book1
	A	B
1	BS00-OLS008-3-OLS	BS00-OLS008-3
2	CF0002-BCLCIRCS1-2-BCLCIRCS	CF0002-BCLCIRCS1-2
3	BF00-BCLCIRCS-027-9-C	BF00-BCLCIRCS-027-9
4	A-OLS-BF00027-C-9-C	A-OLS-BF00027-C-9
Sheet7

Cell Formulas
Range	Formula
B1:B4	B1	=LET( t, A1, rem, {"-OLS";"-BCLCIRCS";"-C"}, remLen, LEN(rem), mt, TEXTJOIN("", 1, IF(RIGHT(t, remLen)=rem, LEFT(t, LEN(t)-remLen), "")), mt )

 

[Scott Huish]

OP has Excel 2019

 

[felixstraube]

Oh, thanks. My mistake.
Here the corrected formula for excel 2019:

Book5.xlsx
	A	B
1	BS00-OLS008-3-OLS	BS00-OLS008-3
2	CF0002-BCLCIRCS1-2-BCLCIRCS	CF0002-BCLCIRCS1-2
3	BF00-BCLCIRCS-027-9-C	BF00-BCLCIRCS-027-9
Sheet7

Cell Formulas
Range	Formula
B1:B3	B1	=CONCAT(IF(RIGHT(A1,LEN({"-OLS";"-BCLCIRCS";"-C"}))={"-OLS";"-BCLCIRCS";"-C"},LEFT(A1,LEN(A1)-LEN({"-OLS";"-BCLCIRCS";"-C"})),""))