Changing Multiple chart references within a selection

[SquareHouse]

I have a macro that goes through all the charts in my workbook and changes the series inputs (in this case would change row 18 reference to row 19 but can obviously be amended as needed)
I'd like to amend this macro so that I can just amend the charts in my selection instead of the entire workbook
I know this must be an easy fix, but haven't had any luck in getting my tries to work

Thanks in advance

sub changeallcharts()

Dim sht As Worksheet
Dim cht As ChartObject
Dim ser As Series

For Each sht in ActiveWorkbook.worksheets
      For Each cht in sht.ChartObjects
              For Each ser In cht.Chart.SeriesCollection
                         ser.formula = replace(ser.Formula, "$18","$19")
              Next ser
      Next cht
Next sht
MsgBox("All Done")

end sub

 

[RoryA]

Try something like this:

Sub changeSelectedCharts()

    Dim cht As Object
    
    On Error Resume Next
    Set cht = ActiveChart
    On Error GoTo 0
    
    If Not cht Is Nothing Then ' one chart selected
        ChangeChart cht
        MsgBox ("All Done")
    Else
        Dim whatSelected As Object
        Set whatSelected = Selection
        If TypeName(whatSelected) = "DrawingObjects" Then
        
            For Each cht In whatSelected
            
                If TypeName(cht) = "ChartObject" Then ChangeChart cht.Chart
                
            Next cht
            
            MsgBox ("All Done")
            
        End If
    End If
End Sub
Sub ChangeChart(cht As Chart)
    Dim ser As Series
    For Each ser In cht.SeriesCollection
        ser.Formula = Replace(ser.Formula, "$18", "$19")
    Next ser
End Sub

 

[SquareHouse]

thanks will try out asap