Changing a form control with a form control

[sinner8]

I am in desperate need of some help with some form controls. I need a way to manipulate a group of check box forms and/or combo box forms with a macro assigned to a single form control. For example, clicking a single "check box A" would check off all the boxes in an associated group. Is this possible? Thanks to anybody who can help!

 

[mikerickson]

If you link each of the check boxes in a "group" to the same cell, they will change all together. No macro needed.

 

[sinner8]

Mikerickson,

Thanks for your help! The issue I have with that method is that I need to have the subset boxes control linked cells independently. I have attached a link to an image displaying an example of what I am trying to accomplish. I simply need a "master checkbox to turn on or off a larger subset while maintaining the ability to manipulate each box in the subset individually. Thanks to anybody for the help!!!

View image: Form Control question

 

[mikerickson]

You could assign this macro to each of you master checkboxes. Note that this code uses the Name of the check box, not its Caption. And that spaces and case sensitivity are important. Also, a box could (potentially) be the daughter boxes to more than one mother. Also a mother box could be the daughter to another box, just make sure to avoid circularity (i.e. no box is its own great-great----daughter).

Sub test()
    Dim MotherBox As Object
    Dim DaughterBoxNames As Variant
    Dim oneName As Variant
    
    If TypeName(Application.Caller) = "String" Then
        Set MotherBox = ActiveSheet.Shapes(Application.Caller)
    Else
        MsgBox "call this routine only by clicking a forms check box"
        Exit sub
    End If
    
    Select Case MotherBox.Name
        Case "Check Box A"
            DaughterBoxNames = Array("Check Box1a", "Check Box 2", "Check Box 3")
        Case "Check Box B"
            DaughterBoxNames = Array("Check Box 6", "Check Box 8", "Check Box 9", "Check Box 2")
    End Select
    
    
    For Each oneName In DaughterBoxNames
        ActiveSheet.Shapes(oneName).ControlFormat.Value = MotherBox.ControlFormat.Value
    Next oneName
End Sub