Change VBA code to absolute value

[wildturkey]

Morning All

I have the following code which I've picked up from the internet and it all works great, however, and with little knowledge, Id like to change the ability to chose the range of rows to an absolute value of rows 28 to 60, so that only blank rows in this range are ignored when printing. Any help appreciated..

Sub Print_NonBlank_Rows()
'Updateby Extendoffice 20160704
Dim xStr As String
Dim xRg As Range
Dim xHideRg As Range
Dim xTxt As String
Dim I As Long
On Error Resume Next
If ActiveWindow.RangeSelection.Count > 1 Then
xTxt = ActiveWindow.RangeSelection.AddressLocal
Else
xTxt = ActiveSheet.UsedRange.AddressLocal
End If
Set xRg = Application.InputBox("please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
If xRg Is Nothing Then Exit Sub
Application.ScreenUpdating = False
For I = 1 To xRg.Rows.Count
If Application.WorksheetFunction.CountA(xRg.Rows(I)) = 0 Then
If xHideRg Is Nothing Then
Set xHideRg = xRg.Rows(I)
Else
Set xHideRg = Union(xHideRg, xRg.Rows(I))
End If
End If
Next
xHideRg.EntireRow.Hidden = True
ActiveSheet.PrintOut Copies:=1
xHideRg.EntireRow.Hidden = False
Application.ScreenUpdating = True
End Sub

 

[footoo]

Sub Print_NonBlank_Rows()
Dim xHideRg As Range, I As Long
Application.ScreenUpdating = False
For I = 28 To 60
    If Application.WorksheetFunction.CountA(Rows(I)) = 0 Then
        If xHideRg Is Nothing Then
            Set xHideRg = Rows(I)
        Else
            Set xHideRg = Union(xHideRg, Rows(I))
        End If
    End If
Next
On Error Resume Next
xHideRg.EntireRow.Hidden = True
ActiveSheet.PrintOut Copies:=1
xHideRg.EntireRow.Hidden = False
Application.ScreenUpdating = True
End Sub

 

[wildturkey]

Thanks for the reply, does what I asked for, but I think I jumped the gun assuming the first version worked, both exclude blank rows from printing, but I also need blank rows with formula in them to be skipped - is this an easy tweak please?

 

[footoo]

Sub Print_NonBlank_Rows()
Dim xHideRg As Range, I As Long
Application.ScreenUpdating = False
For I = 28 To 60
   If Application.WorksheetFunction.CountBlank(Rows(I)) = Columns.Count Then
        If xHideRg Is Nothing Then
            Set xHideRg = Rows(I)
        Else
            Set xHideRg = Union(xHideRg, Rows(I))
        End If
    End If
Next
On Error Resume Next
xHideRg.EntireRow.Hidden = True
ActiveSheet.PrintOut Copies:=1
xHideRg.EntireRow.Hidden = False
Application.ScreenUpdating = True
End Sub

 

[wildturkey]

Perfect!