change sheet automatically

[annadinesh]

1 have 3 sheets

SHEET 1. Details
SHEET 2. SOT
SHEET 3. EW

I want if active sheet was EW or SOT, then it should automatically return to sheet 1 after 30 Sec of inactivity

Regards


Dinesh Saha

 

[PeteWright]

This can (only) be done with VBA.
Save your workbook as *.xlsm (Macro-enabled Workbook) and open the VBA Editor by pressing [ALT]+[F11], then set up as follows:

Display the Project Explorer

right-click on your workbook

insert a new Module

paste the following code into the new module

Public IdleTime

Sub SwitchSheet()
   ThisWorkbook.Sheets("Details").Activate
End Sub

Sub StartTimer()
   IdleTime = Now + TimeValue("00:01:30")
   Application.OnTime IdleTime, "SwitchSheet"
End Sub

Sub StopTimer()
   On Error Resume Next
   Application.OnTime IdleTime, "SwitchSheet", , False
End Sub

Paste this to the Worksheet section of Sheet1 (Details)

Private Sub Worksheet_Deactivate()
   Call StopTimer
   Call StartTimer
End Sub

Paste this to the Workbook Code

Private Sub Workbook_Open()
   Call StartTimer
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
   Call StopTimer
   Call StartTimer
End Sub

Private Sub Workbook_SheetCalculate(ByVal Sh As Object)
   Call StopTimer
   Call StartTimer
End Sub

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
   Call StopTimer
   Call StartTimer
End Sub

Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
   Call StopTimer
   Call StartTimer
End Sub

If you have any questions let me know