change format cell of text

[amiroo]

hi guys

I want change format of text and put some / in it

for example: (put / after second character)
Excel => Ex/cel
Hello => He/llo


does it possible? Of course without vba

 

[Peter_SSs]

You can do it with a formula in another column. For example: =REPLACE(A1,3,0,"/")

 

[amiroo]

You can do it with a formula in another column. For example: =REPLACE(A1,3,0,"/")

thanks dear peter. but I need use format cell because I can't use second column. the only way is using format cell or vba

 

[Peter_SSs]

the only way is using format cell or vba

Then if vba is now allowed, you can try this Worksheet_Change code in a new workbook. To implement ..
1. Right click the sheet name tab and choose "View Code".
2. Copy and Paste the code below into the main right hand pane that opens at step 1.
3. Close the Visual Basic window & test.
4. Your workbook will need to be saved as a macro-enabled workbook (*.xlsm).

Note that the code targets values entered into column A from row 2 down. If this needs to be changed and you are unable to do so yourself, post back with details of the target area.

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim Changed As Range, c As Range
  Dim s As String
  
  Set Changed = Intersect(Target, Columns("A"), Rows("2:" & Rows.Count))
  If Not Changed Is Nothing Then
    Application.ScreenUpdating = False
    Application.EnableEvents = False
    For Each c In Changed
      s = c.Value
      If Len(s) > 1 Then
        If Mid(s, 3, 1) <> "/" Then
          c.Value = Replace(s, Left(s, 2), Left(s, 2) & "/", 1, 1)
        End If
      End If
    Next c
    Application.EnableEvents = True
    Application.ScreenUpdating = True
  End If
End Sub