Change font colors with one shortcut.

[db317]

Hello all,

I was trying to create a shortcut that could change the font color of the selected cell.
Here is what I want to achieve:
1. There needs to be only one shortcut, for example "Ctrl+Alt+H"
2. When I use the shortcut, it changes the font color in selected cells to black.
3. When I use the shortcut on selected cells again, it changes the font color to blue.
4. Use the shortcut again and it changes the selected font color to red.
5. Then green.

I was trying to do it with a "If, Elseif" function but it didn't work out.

Please help me with this. I appreciate all your help

 

[StephenCrump]

Welcome to the Forum!

Perhaps something like this:

'In the ThisWorkbook module
Private Sub Workbook_Open()
    
    Application.OnKey "+^{H}", "ChangeFontColor"

End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)

    Application.OnKey "+^{H}"

End Sub
'In a standard code module
Private Sub ChangeFontColor()
            
    Dim c As Range
    
    For Each c In Selection
        With c.Font
            Select Case .Color
            Case vbBlack
                .Color = vbBlue
            Case vbBlue
                .Color = vbRed
            Case vbRed
                .Color = vbGreen
            Case Else
                .Color = vbBlack
            End Select
        End With
    Next c

End Sub

 

[pvr928]

Hi StephenCrump

Nice code. I needed to change the ChangeFontColor() so it was not Private, ie:

Sub ChangeFontColor()

Also, the shortcut key combination that works is 'Ctrl+Shift+H' not 'Ctrl+Alt+H' - is there a particular script for 'Ctrl-Alt-H'?

Cheers

pvr928

 

[StephenCrump]

I needed to change the ChangeFontColor() so it was not Private

OK, but I'm not clear why it wouldn't have worked as a Private Sub.

Also, the shortcut key combination that works is 'Ctrl+Shift+H' not 'Ctrl+Alt+H' - is there a particular script for 'Ctrl-Alt-H'?

Oops, my mistake (I use custom CTRL-SHIFT shortcuts myself).

The Developer Reference Help for Application.OnKey method has a full list. ALT is %

 

[pvr928]

Thanks StephenCrump

I just changed it back to Private Sub ChangeFontColor() and it works - not sure why it wasn't previously

Cheers

pvr928

 

[db317]

This is really helpful, thank you very much StephenCrump