Capture cmd result without opening command prompt window or creating temporary file or .bat file, or without using python or others, possible?

[ballgnm]

Hello guys. I need to get version of my installed selenium chromedriver.exe in vba.
But I couldn't find good silent method.

shell.exec always opens command prompt window that pops up.
Is there truly silent way to do it?

Or any alternative way to get version of chromedriver in vba without using python or similar third party app or without creating temp files?

 

[John_w]

get version of chromedriver in vba

    Debug.Print CreateObject("Scripting.FileSystemObject").GetFileVersion(Environ("localappdata") & "\SeleniumBasic\chromedriver.exe")

 

[ballgnm]

    Debug.Print CreateObject("Scripting.FileSystemObject").GetFileVersion(Environ("localappdata") & "\SeleniumBasic\chromedriver.exe")

It gives me empty string.

 

[John_w]

That command reads the chromedriver.exe file properties, however they're blank. By contrast, edgedriver.exe properties aren't blank.

A version number is displayed when I run chromedriver.exe, but I haven't found a way of reading it.

 

[John_w]

Try this:

Public Sub ChromeDriver_Version()

    Dim line1 As String
    
    'Run chromedriver.exe, read first line of output and extract version number
    
    With CreateObject("WScript.Shell")
        line1 = .Exec(Chr(34) & Environ("localappdata") & "\SeleniumBasic\chromedriver.exe" & Chr(34)).StdOut.ReadLine
    End With
    Debug.Print Split(line1, " ")(2)
    
    Shell "TaskKill /IM chromedriver.exe", vbHide
    
End Sub

Note that a command window is displayed briefly, however this is unavoidable with the Windows Script Host Shell Exec method. The alternative of running chromedriver.exe with the Run method, which can hide the command window, and redirecting the output to a file doesn't work because the file isn't created.

 

[ballgnm]

Note that a command window is displayed briefly, however this is unavoidable with the Windows Script Host Shell Exec method.

Yeah. Unfortunately.
Tried .exec and .run before I come here and post.
Thought there would be alternative without installing third party apps.
I'll just use .Run in window hidden mode and create and delete temporary file I guess.

 

[John_w]

I'll just use .Run in window hidden mode and create and delete temporary file I guess.

I'd like to see your code if you can get that to work.

 

[ballgnm]

Sure.

Sub ChromeDriverCheck()
    Dim vChromeDriver, driverPath, ChromeDriverEXE, cmdChrome, tempFile As String

    driverPath = Environ("LocalAppData") & "\SeleniumBasic\"
    ChromeDriverEXE = driverPath & "chromedriver.exe"
    tempFile = driverPath & "TemporaryFileForDriverVersionCheck.txt"
    cmdChrome = "cmd /c """ & driverPath & "chromedriver.exe" & """ --version > " & tempFile
    
    If Dir(ChromeDriverEXE) <> "" Then
        VBA.CreateObject("WScript.Shell").Run cmdChrome, 0, True
        Open tempFile For Input As #1
        vChromeDriver = Input$(LOF(1), 1)
        Close #1
        Kill tempFile
        vChromeDriver = Split(vChromeDriver, " ")(1)
    Else
        vChromeDriver = ""
    End If
    
    Debug.Print vChromeDriver
End Sub

 

[John_w]

Ahaa! I didn't know about the --version switch, which makes chromedriver.exe run and exit immediately. Without it, I had to TaskKill the process which meant the output file wasn't created.