Can we copy and paste Filter data?

[santoshloka]

I want to paste all this filter values need to place in FINISHED ROAD LEVEL LHS("REPLACE X")


is there any macro for this?
please find the attachment below

https://drive.google.com/open?id=0B8-usD7SI_4aS3lvT0ZZR2hDTTg
https://drive.google.com/open?id=0B8-usD7SI_4adWdWY1lLbDNZZzg

 

[Fluff]

Try

Sub CopyFltrData()

    Dim Usdrws As Long

    Usdrws = Range("M" & Rows.Count).End(xlUp).Row
    Range("F2:F" & Usdrws).SpecialCells(xlVisible) = Range("M2:M" & Usdrws).SpecialCells(xlVisible)

End Sub

 

[santoshloka]

only 1st value is changing..(this is filter data)

please find the attachment link below
https://drive.google.com/open?id=0B8-usD7SI_4aNjFYb1Yzd2E4YU0

 

[Fluff]

My mistake, try this

Sub CopyFltrData()

    Dim Usdrws As Long

    Usdrws = Range("M" & Rows.Count).End(xlUp).Row
    With Range("F2:F" & Usdrws).SpecialCells(xlVisible)
        .FormulaR1C1 = "=rc[7]"
        .Value = .Value
    End With

End Sub

 

[santoshloka]

if yu remove
.value=.value
its working fine
ty for code

 

[Fluff]

Glad to help & thanks for the feedback.
Can't figure out why the .value=.value doesn't work.

 

[santoshloka]

is there any alternative way to get .value=.value
this will be very helpful can u please work on it

 

[Fluff]

2 options
1) No loops, but removes the filter

Sub CopyFltrData()

    Dim Usdrws As Long

Application.ScreenUpdating = False

    Usdrws = Range("M" & Rows.Count).End(xlUp).Row
    Range("F2:F" & Usdrws).SpecialCells(xlVisible).FormulaR1C1 = "=rc[7]"
    ActiveSheet.ShowAllData
    Columns(6).Value = Columns(6).Value
    
End Sub

2) Keeps the filtered range, but loops

Sub CopyFltrData2()

    Dim Usdrws As Long
    Dim Cl As Range

    Usdrws = Range("M" & Rows.Count).End(xlUp).Row
    For Each Cl In Range("F2:F" & Usdrws).SpecialCells(xlVisible)
        Cl.Value = Cl.Offset(, 7)
    Next Cl

End Sub

 

[santoshloka]

Awsome thank you

 

[Fluff]

Glad to help & thanks for the feedback