Calling Sub by Variable Name

[hellsreach]

I am trying to can one of several macros by variable name and not sure how.

Sub myMacro()

Dim myArray(2) as Variant

myArray(0) = "A"
myArray(1) = "B"
myArray(2) = "C"

For I = 0 to 2
Call myArray(I) ' -- clearly, this wont work!!!
Next I

End Sub

Private Sub A()
...
End Sub


Private Sub B()
...
End Sub


Private Sub C()
...
End Sub

 

[MickG]

You could do this:-

Sub myMacro()
 Dim myArray(2) As Variant
 Dim I As Long
 myArray(0) = "A"
 myArray(1) = "B"
 myArray(2) = "C"
 For I = 0 To 2
    Select Case True
        Case myArray(I) = "A": Call A
        Case myArray(I) = "B": Call B
        Case myArray(I) = "C": Call C
    End Select
 Next I
 End Sub

 

[tlowry]

Or, you could use the

Run

command.

Option Explicit

Sub myMacro()
    Dim i
    Dim myArray()
    myArray = Array("Asub", "Bsub", "Csub")
    For i = 0 To UBound(myArray)
        Application.Run myArray(i)
    Next i
End Sub
Private Sub Asub()
    MsgBox "This is sub Asub"
End Sub
Private Sub Bsub()
    MsgBox "This is sub Bsub"
End Sub
Private Sub Csub()
    MsgBox "this is sub Csub"
End Sub