Calculating Tiered Commission for Sales People 😁

K

koki52594

New Member
Joined
Mar 6, 2023
Messages
4
Office Version
  1. 365
Platform
  1. MacOS
Hi guys! Hope all of you are doing well and healthy.

I need some help here creating a formula that will help me to calculate the commissions for salespeople based on the tiers below:

Tier 1 - Sales Up to $20,000.00 - Not Eligible for Commission
Tier 2 - Greater than $20,000.01 up to $50,000.00 in Sales will pay 6% of the Excess of $20,000.01
Tier 3 - Greater than $50,000.01 up to $80,000.00 in Sales will pay 8% of the Excess of $50,000.01
Tier 4 - Greater than $80,000.01 up to $100,000.00 in Sales will pay 10% of the Excess of $80,000.01
Tier 5- Greater than $100,000.01 in Sales will pay 8% of the Excess of $100,000.01

Let me know if you need more details so that I can help you.

Thank you so much!
 

Excel Facts

Test for Multiple Conditions in IF?
Use AND(test, test, test, test) or OR(test, test, test, ...) as the logical_test argument of IF.
Sort by date Sort by votes
Try this
Excel Formula: 
=IF(A1<=20000,0,IF(A1<=50000,(A1-20000)*0.06,IF(A1<=80000,(A1-50000)*0.08+1800,IF(A1<=100000,(A1-80000)*0.1+4200,(A1-100000)*0.08+6200))))


Or this
Excel Formula: 
=SUMPRODUCT((A1>20000)*(A1>{0,20000,50000,80000,100000})*((A1-{0,20000,50000,80000,100000})*{0,0.06,0.08,0.1,0.08}+{0,0,1800,4200,6200}))
 
Last edited:
Upvote 1
Thank you so much!

How the formula would look with changing the commission tiers to:

Tier 1: 0%
Tier 2: 4%
Tier 3: 6%
Tier 4: 8%
Tier 5: 6%
 
Upvote 0
Try
Excel Formula: 
=IF(A1<=20000, 0, IF(A1<=50000, (A1-20000)*0.04, IF(A1<=80000, (A1-50000)*0.06+1200, IF(A1<=100000, (A1-80000)*0.08+3600, (A1-100000)*0.06+5600))))

Or this
Excel Formula: 
=IF(A1<=20000,0,IF(A1<=50000,(A1-20000)*0.04,IF(A1<=80000,(A1-50000)*0.06+1200,IF(A1<=100000,(A1-80000)*0.08+3000,(A1-100000)*0.06+4600))))
 
Last edited:
Upvote 1
Another alternative.
With C1, you do not have to maintain the table of brackets and rates.
I used Name Manager and named the Bracket information and the rate differential information.

Commissions 2023.xlsm
ABC
1100,000.004,600.004,600.00
2
300%
420,0004%
550,0006%
680,0008%
7100,0006%
8
1c
Cell Formulas
RangeFormula
B1B1=SUM((A1>B3:B7)*(A1-B3:B7)*(C3:C7-C2:C6))
C1C1=SUM((A1>aB)*(A1-aB)*aR)
 
Upvote 0
snjpverma said:
Try
Excel Formula: 
=IF(A1<=20000, 0, IF(A1<=50000, (A1-20000)*0.04, IF(A1<=80000, (A1-50000)*0.06+1200, IF(A1<=100000, (A1-80000)*0.08+3600, (A1-100000)*0.06+5600))))

Or this
Excel Formula: 
=IF(A1<=20000,0,IF(A1<=50000,(A1-20000)*0.04,IF(A1<=80000,(A1-50000)*0.06+1200,IF(A1<=100000,(A1-80000)*0.08+3000,(A1-100000)*0.06+4600))))
Click to expand...

I am having problems with this second formula, when I make the calculations manually the numbers don't add up correctly.

Would you be so kind of revising the formula?

Looking forward to your thoughts,
 
Upvote 0
"I am having problems with this second formula, when I make the calculations manually the numbers don't add up correctly.
Would you be so kind of revising the formula? Looking forward to your thoughts,"

What is the problem?
What numbers did you use?
Please show your calculations.

Commissions 2023.xlsm
ABCD
140,000.00800.00800.00800.00
1c
Cell Formulas
RangeFormula
B1B1=SUM((A1>B3:B7)*(A1-B3:B7)*(C3:C7-C2:C6))
C1C1=SUM((A1>aB)*(A1-aB)*aR)
D1D1=IF(A1<=20000,0,IF(A1<=50000,(A1-20000)*0.04,IF(A1<=80000,(A1-50000)*0.06+1200,IF(A1<=100000,(A1-80000)*0.08+3000,(A1-100000)*0.06+4600))))
 
Upvote 0
Dave Patton said:
"I am having problems with this second formula, when I make the calculations manually the numbers don't add up correctly.
Would you be so kind of revising the formula? Looking forward to your thoughts,"

What is the problem?
What numbers did you use?
Please show your calculations.

Commissions 2023.xlsm
ABCD
140,000.00800.00800.00800.00
1c
Cell Formulas
RangeFormula
B1B1=SUM((A1>B3:B7)*(A1-B3:B7)*(C3:C7-C2:C6))
C1C1=SUM((A1>aB)*(A1-aB)*aR)
D1D1=IF(A1<=20000,0,IF(A1<=50000,(A1-20000)*0.04,IF(A1<=80000,(A1-50000)*0.06+1200,IF(A1<=100000,(A1-80000)*0.08+3000,(A1-100000)*0.06+4600))))
Click to expand...
Hi Dave!

I corrected the problem with the formula that was provided by @snjpverma

The problem was here (Bold part and underlined) :

=IF(A1<=20000, 0, IF(A1<=50000, (A1-20000)*0.04, IF(A1<=80000, (A1-50000)*0.06+1200, IF(A1<=100000, (A1-80000)*0.08+3600, (A1-100000)*0.06+5600))))

$3,600 is not the correct sum of the maximum commission of both Tier 1 (4% of 30,000 = 1,200) and Tier 2 (6% of 30,000 = 1,800) combined, the correct number is 3,000.

The same happened with the $5,600. When we sum the maximum commission of Tier 1, Tier 2 and Tier 3 is $4,600, not $5,600.

That's why the numbers were wrong.

Here is the correct formula:

=IF(B60<=20000,0,IF(B60<=50000,(B60-20000)*0.04,IF(B60<=80000,(B60-50000)*0.06+1200,IF(B60<=100000,(B60-80000)*0.08+3000,(B60-100000)*0.06+4600))))

Thank you so much!
 
Upvote 0
koki52594 said:
.

Here is the correct formula:

=IF(B60<=20000,0,IF(B60<=50000,(B60-20000)*0.04,IF(B60<=80000,(B60-50000)*0.06+1200,IF(B60<=100000,(B60-80000)*0.08+3000,(B60-100000)*0.06+4600))))

Thank you so much!
Click to expand...
This is the exact formula in post # 4. Check the 2nd formula
 
Upvote 0
Solution
A standard LOOKUP (V or X) problem.
Book1
ABCDEFG
1SalesCommissionSalesEligible SalesCommish %Commission
20.000%137,757.0037,756.998%3,020.56
320,000.000%113,532.0013,531.998%1,082.56
420,000.016%32,513.0012,512.996%750.78
550,000.018%139,085.0039,084.998%3,126.80
680,000.0110%22,627.002,626.996%157.62
7100,000.018%144,789.0044,788.998%3,583.12
836,505.0016,504.996%990.30
9120,985.0020,984.998%1,678.80
1030,758.0010,757.996%645.48
1192,113.0012,112.9910%1,211.30
12145,711.0045,710.998%3,656.88
1360,811.0010,810.998%864.88
14119,981.0019,980.998%1,598.48
15137,322.0037,321.998%2,985.76
1693,606.0013,605.9910%1,360.60
1751,026.001,025.998%82.08
1870,014.0020,013.998%1,601.12
1981,709.001,708.9910%170.90
2056,231.006,230.998%498.48
2137,104.0017,103.996%1,026.24
Sheet1
Cell Formulas
RangeFormula
D2:D21D2=RANDARRAY(20,,19000,150000,1)
E2:E21E2=D2#-XLOOKUP(D2#,Commish[Sales],Commish[Sales],,-1)
F2:F21F2=XLOOKUP(D2#,Commish[Sales],Commish[Commission],,-1)
G2:G21G2=XLOOKUP(D2#,Commish[Sales],Commish[Commission],,-1)*E2#
Dynamic array formulas.

The formulas in columns E to G can easily be combined into a single formula. I used separate columns to be clearer.
 
Upvote 0
You must log in or register to reply here.

Similar threads

Y
  • Question Question
Multi tiered commission structure formula help
Replies
2
Views
128
Dave Patton
D
staticfluids
  • Solved
Dynamic Array Formula (FILTER) But Show the Other Criteria with Blank
Replies
4
Views
518
staticfluids
staticfluids
R
  • Question Question
Formula for commission structure
Replies
9
Views
842
MARK858
MARK858
E
  • Question Question
Calculating Tiered Commission Structure based on Rolling Annual Contribution
Replies
1
Views
1K
Dave Patton
D
A
  • Locked
  • Question Question
Match customer and calculate commission basis their respective slabs
Replies
2
Views
317
Peter_SSs
Peter_SSs

Forum statistics

Threads
1,224,823
Messages
6,181,177
Members
453,021
Latest member
Justyna P

Share this page

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top