Calculate Time Formula

[esgca2010]

I would like to calculate the difference between start time and end time AND have the result appear in "quarters".

Examples:
B9 C9 E9
Start Time End Time Result
7:00am 10:30am 3.50
7:00am 10:15am 3.25
7:00am 10:45am 3.75

I thank you in advance for your support.

It is truly appreciated.

Respectfully,

Elaine

 

[joeu2004]

E9: =MROUND((C9-B9+(C9<=B9))*24, 0.25)

formatted as General or Number with 2 decimal places.

The (C9<=B9) factor allows for time periods within 24 hours spanning across midnight. For example, 7:00 PM and 10:30 AM.

 

[esgca2010]

E9: =MROUND((C9-B9+(C9<=B9))*24, 0.25)

formatted as General or Number with 2 decimal places.

The (C9<=B9) factor allows for time periods within 24 hours spanning across midnight. For example, 7:00 PM and 10:30 AM.

------------------------------
Awesome thank you but can you help me with an if statement that I applied to your formula?

I there are no times in cells C9, and B9 I get a result of 24. How do I modify the formula to show the cell blank if there are no times?

=IF($D$9="Recovery Services",MROUND(($C$9-$B$9+($C$9<=$B$9))*24,0.25),"")

Thank you, thank you, thank you! You are the BEST!!!

Elaine

 

[joeu2004]

=IF(AND(D9="Recovery Services", COUNT(B9,C9)=2), MROUND((C9-B9+(C9<=B9))*24, 0.25), "")

Note my use of relative references without dollar signs ("$"). Those reference change as you copy the formula down the column. I presume you would want that. Or it is just easier to type, if you do not intend to copy the formula.

You only need to use absolute references with dollar signs for cell references that should not change when you copy the formula.

 

[esgca2010]

=IF(AND(D9="Recovery Services", COUNT(B9,C9)=2), MROUND((C9-B9+(C9<=B9))*24, 0.25), "")

Note my use of relative references without dollar signs ("$"). Those reference change as you copy the formula down the column. I presume you would want that. Or it is just easier to type, if you do not intend to copy the formula.

You only need to use absolute references with dollar signs for cell references that should not change when you copy the formula.

---------

You are AWESOME!!! I was using the OR statement!

Thank you for your support! You are a life saver. I can have a good weekend.

Elaine