Calculate time between occurrences

[bmv505]

I have a spreadsheet with years of team scoring plays (Team "L" and its Opponent "O")

The scoring plays have a time, which I calculate on a one hour range (60 minute football game, so if theres 11:55 left in the 1st quarter, the "game time" is 56:55, which I use time formula "time(0,56,55)" to represent)

I am trying to find a formula that calculates the time between a team's scores. So in screenshot below,

Coulmn A is year
Column B is the game number of that year
Column D is the quarter
Column F is the minute of the quarter
Column G is the second of the quarter
Column H shows what team scores ("L" or "O", with "Game" being the start and end of a game)
Column T is the game time (which I believe will make it a lot cleaner to calculate)

Thank you!

 

[JGordon11]

Book1
	A	B		D		F	G	H												T							AA		AC	AD
1	Year	Game		Q		M	S	L/O/G												Game Time							Time between L scores		Time between O scores
2	2023	1		1		15	0	Game												1:00:00
3	2023	1		1		11	55	L												0:56:55							1st score
4	2023	1		1		4	49	O												0:49:49									1st score
5	2023	1		2		11	39	L												0:41:39							0:15:16
6	2023	1		2		9	9	L												0:39:09							0:02:30
7	2023	1		2		2	17	O												0:32:17									0:17:32
8	2023	1		3		9	28	L												0:24:28							0:14:41
9	2023	1		4		14	55	L												0:14:55							0:09:33
10	2023	1		4		4	59	L												0:04:59							0:09:56
11	2023	1		4		2	1	O												0:02:01									0:30:16
12	2023	1		4		0	0	Game												0:00:00
13	2023	2		1		15	0	Game												1:00:00
14	2023	2		1		10	59	L												0:55:59							1st score
15	2023	2		1		10	26	O												0:55:26									1st score
16	2023	2		1		3	32	L												0:48:32							0:07:27
17	2023	2		2		12	0	O												0:42:00									0:13:26
18
Sheet5

Cell Formulas
Range	Formula
T2:T17	T2	=(60-(D2-1)*15 - (15-F2) + G2/60)/(1440)
AA2:AA17	AA2	=IF(H2="L", IFERROR(TAKE(FILTER(T$1:T1, (A$1:A1=A2)*(B$1:B1=B2)*(H$1:H1="L")),-1) - T2,"1st score"), "")
AC2:AC17	AC2	=IF(H2="O", IFERROR(TAKE(FILTER(T$1:T1, (A$1:A1=A2)*(B$1:B1=B2)*(H$1:H1="O")),-1) - T2,"1st score"), "")