ByRef argument type mismatch

[nanofied]

Hi guys, I am writing a code to check if a user input sheet name exist in the workbook. Here is what I done:

Function SheetExists(SheetName As String)
    On Error GoTo no:
    WorksheetName = Worksheets(SheetName).Name
    SheetExists = True
    Exit Function
no:
    SheetExists = False
End Function

Dim ImportingSheet As String

ImportingSheet = InputBox("Type in the sheet you want to import from (Case sensitive)", "Type Sheet Name", "Email 2018")
    
    If SheetExists(ImportingSheet) Then
        MsgBox "The sheet exist"
    Else
        MsgBox "The sheet does not exist. Check again"
        End
    End If

However I am getting"ByRef argument type mismatch" at the if statement. Any idea what when wrong?

 

[dmt32]

hi,

try passing the argument ByVal and see if this solves the issue.

Function SheetExists(ByVal SheetName As String)
    On Error GoTo no:
    WorksheetName = Worksheets(SheetName).Name
    SheetExists = True
    Exit Function
no:
    SheetExists = False
End Function

Dave

 

[nanofied]

Hi, I have pass the argument as variant. And it work too. Is there any difference between the two?

 

[dmt32]

Hi, I have pass the argument as variant. And it work too. Is there any difference between the two?

The Variant data type can be used for all data types except fixed length strings and user defined types.
A Variant data type automatically works out which data type is the most appropriate based on the value you assign. It can also contain the special values "Empty", "Null" and "Error"

Whilst you can use a Variant in place of any other specified data types to work with data in a more flexible way, it’s not the most efficient way of managing your variables. If you know the data type you are dealing with it’s always best to declare it.

As an aside, you can shorten your function a little

Function SheetExists(ByVal SheetName As String) As Boolean
    On Error Resume Next
    SheetExists = CBool(Len(Worksheets(SheetName).Name) > 0)
    On Error GoTo 0
End Function

Dave

 

[nanofied]

Thank you Dave, I understand. Your help is appreciated

 

[Rick Rothstein]

As an aside, you can shorten your function a little

Function SheetExists(ByVal SheetName As String) As Boolean
    On Error Resume Next
    SheetExists = CBool(Len(Worksheets(SheetName).Name) > 0)
    On Error GoTo 0
End Function

Dave

Actually, since the function is declared as a Boolean and the length of a string can never be minus one, you can shorten the red highlighted line of code to this and the function will still work correctly...

SheetExists = Len(Worksheets(SheetName).Name)

 

[dmt32]

Thank you Dave, I understand. Your help is appreciated

most welcome - glad resolved for you.

Dave