Button that hides and unhides columns

[Romano_odK]

Good afternoon,

In my table "ItemImport" I have the need sometimes to hide a few columns. To hide these with VBA is not that hard, but if you want to do that with one button then its a different story. Would this be possible and so that the button changes its text also. So from Hide to Unhide as text. The below action is what I need.

Thank you in advance and have a great day.

Columns("Q:AT").Select
    Selection.EntireColumn.Hidden = True

 

[DanteAmor]

What type of button do you have on your sheet?
There are several types of buttons and the operation for each of them is different.


I give you 3 codes for the following buttons: ActiveX control CommandButton, ActiveX control togglebutton and a Shape.

Private Sub CommandButton1_Click()
  With CommandButton1
    If .Caption = "Show" Then .Caption = "Hide" Else .Caption = "Show"
    Columns("Q:AT").EntireColumn.Hidden = .Caption = "Show"
  End With
End Sub

Private Sub ToggleButton1_Click()
  With ToggleButton1
    If .Caption = "Show" Then .Caption = "Hide" Else .Caption = "Show"
    Columns("Q:AT").EntireColumn.Hidden = .Caption = "Show"
  End With
End Sub

In the following code, adjust the name of your shape on this line: ActiveSheet.Shapes("Button1").TextFrame2.TextRange.Characters

Sub show_and_hide_columns()
  With ActiveSheet.Shapes("Button1").TextFrame2.TextRange.Characters
    If .Text = "Show" Then .Text = "Hide" Else .Text = "Show"
    Columns("Q:AT").EntireColumn.Hidden = .Text = "Show"
  End With
End Sub

I hope to hear from you very soon
Regards
Dante Amor

 

[Romano_odK]

This is awesome, thank you for your efforts. I used the active X button in this case.