browse for attachments when sending an email

[quintin]

Good day,

I am trying to browse for the attachment when sending an email to a client - I have the email code working okay, I have come up with this...and it's not working, like I would like it to.

many thanks

Private Sub CommandButton1_Click()
    Dim OutApp As Object
    Dim OutMail As Object
Dim qfile As Object

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "test@gmail.com"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .Body = "Hello World!"
        .attachments.Add = qfile

             filepath = Application.GetOpenFilename("PDF Files (*.pdf), *.pdf")
If filepath <> False Then
qfile = filepath

End If
        .display
        '.Send
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

 

[RickXL]

Hi, I think you are quite close.

Try this instead:

Private Sub CommandButton1_Click()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim filepath As Variant

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    'On Error Resume Next
    With OutMail
        .To = "test@gmail.com"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .Body = "Hello World!"
        filepath = Application.GetOpenFilename("PDF Files (*.pdf), *.pdf")
        If Not filepath = False Then .attachments.Add filepath
        .display
        '.Send
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

 

[quintin]

Thank you very much

 

[RickXL]

No problem.