Break up and count concatenated string - text formula

[jjobrien03]

I have a 5,000 strings formatted as such: (in one cell)

0 0 0 0 0 0 0 12 12 12 12 12 15 15 15 15 18 18 25 25 25 25 25 25 25 100 100 100 100 100 100 100 100

These strings may be as long as 300 unique numbers with spaces in between each number. What I want to do is convert each string to the following format:

0 for 7, 12 for 5, 15 for 4, 18 for 2, 25 for 7, 100

Keeping in mind that both the numbers in between spaces and number of occurrences will be different for each string.

Appreciate any help, am familiar enough with VBA to use that as a solution as well.

 

[Rick Rothstein]

Give this UDF (user defined function) a try...

[table="width: 500"]
[tr]
	[td]Function ForCount(S As String)
  Dim X As Long, Kys As Variant, Nums() As String
  Nums = Split(S)
  With CreateObject("Scripting.Dictionary")
    For X = 0 To UBound(Nums)
      .Item(Nums(X)) = .Item(Nums(X)) + 1
    Next
    Kys = Split(Join(.keys))
    For X = 1 To .Count
      ForCount = ForCount & ", " & Kys(X - 1) & " for " & .Item(Kys(X - 1))
    Next
  End With
  ForCount = Mid(ForCount, 3)
End Function[/td]
[/tr]
[/table]

HOW TO INSTALL UDFs
------------------------------------
If you are new to UDFs, they are easy to install and use. To install it, simply press ALT+F11 to go into the VB editor and, once there, click Insert/Module on its menu bar, then copy/paste the above code into the code window that just opened up. That's it.... you are done. You can now use ForCount just like it was a built-in Excel function. For example,

=ForCount(A1)

If you are using XL2007 or above, make sure you save your file as an "Excel Macro-Enabled Workbook (*.xlsm) and answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

 

[jjobrien03]

Thank you very much, this is great